»  Home »  Resources & support »  FAQs »  Logistic regression with aggregated data

How can I do logistic regression or multinomial logistic regression with aggregated data?

Title   Logistic regression with aggregated data
Author William Sribney, StataCorp

One way to do this is to first rearrange your data so you can use frequency weights (fweights) with the logistic, logit, or mlogit command.

For binary outcomes, one can also use glm with family(binomialvarnameN) and link(logit), where varnameN is a variable that stores the total number of trials for each observation. However, rearranging the data for use with frequency weights also covers the more general case of multinomial outcomes.

It is easier to explain with an example. First, consider the following binary-outcome data:

 . list

  cases total x1 x2
1. 23 123 0 0
2. 12 234 0 1
3. 56 248 1 0
4. 81 390 1 1

In the above dataset, the variable cases contains the number of observations out of total with positive outcomes. For example, in the first line there are 23 observations that are positive and 100 observations that are zero with x1 = 0 and x2 = 0; the total number of observations with x1 = 0 and x2 = 0 is 123.

To use logistic and logit with fweights, the data need to be rearranged such that we have one observation per response category:

 . list , sep(0)

  w y x1 x2
1. 100 0 0 0
2. 23 1 0 0
3. 222 0 0 1
4. 12 1 0 1
5. 192 0 1 0
6. 56 1 1 0
7. 309 0 1 1
8. 81 1 1 1

I this dataset, y is the outcome and w is the frequency number.

You can then run commands such as

 . logit y x1 x2 [fw=w]

We could fit the same model using the glm command:

 . glm cases x1 x2, family(binomial total) link(logit)

This glm specification gives the same answer as the logit command with the rearranged data. However, logit or logistic have advantages in that one can run other commands afterward like estat gof.

To rearrange the data from the first format to the second format, you can use the reshape command.

Here is how you do it for this example:

. input cases total x1 x2

         cases      total         x1         x2
  1. 23 123 0 0
  2. 12 234 0 0
  3. 56 248 1 0
  4. 81 390 1 1
  5. end

. 
. *rearrange
. generate w0 = total - cases

. drop total

. rename cases w1

. generate id=_n

. reshape long w, i(id) j(y)
(note: j = 0 1)

Data wide -> long
Number of obs. 4 -> 8 Number of variables 5 -> 5 j variable (2 values) -> y xij variables: w0 w1 -> w
. drop id

The categories (0, 1, i.e., the suffixes of w) will appear in the variable y. The frequency weights will be given in the new variable w.

Then one can do the regression like

 . logit y x1 x2 [fw=w]
 . mlogit y <covariates> [fw=w]
 
 etc....
 

Stata

Shop

Support

Company


The Stata Blog: Not Elsewhere Classified Find us on Facebook Follow us on Twitter LinkedIn Google+ YouTube
© Copyright 1996–2017 StataCorp LLC   •   Terms of use   •   Privacy   •   Contact us