1 item has been added to your cart.

Stata 6: Why is post giving a syntax error?

The syntax of post is

        post postname exp exp ... exp

Remember the way this works: you first open a postfile using the postfile command, then issue one or more post commands, and finally close the file using postclose.

        postfile  postname varlist using filename, [double every(#) replace ]

        post      postname exp exp ... exp

        postclose postname

If we had it to do over again, the syntax of post would be

        post postname (exp) (exp) ... (exp)

Note the parentheses around the expressions. We recommend you pretend those parentheses are required and type them. Here’s why:

        . postfile myfile a b using myres.dta

        . post myfile (3) (-2)                   <-- this works

        . post myfile 3 -2                       <-- yet this does not!
        invalid syntax
        r(198);

Why does “post myfile 3 -2” not work? Because post assumes its arguments are expressions and spaces are not significant in expressions. post sees “3 -2”, and that is the same as seeing “3-2” — it looks like an expression that evaluates to 1.

You typed “post myfile 3 -2”, but that is the same as

        . post myfile 3-2

which is the same as

        . post myfile 1

and that is too few expressions. Since you specified two variables in the opening postfile, post now expects two expressions but found only one!

Understand that had you typed

        . post myfile 3 1-3

post would have understood you because it could see where one expression ended and the next began; but “3 -2” could just be “3-2”, which is to say, an expression that evaluates to 1.

The solution is to type parentheses around post’s arguments, and it will not hurt to do so even when it is unnecessary:

        . post myfile (3) (-2)
        . post myfile (3) (1-3)

You especially need to do this when the arguments to post are macros because macros are substituted. The following program works:

        program define demo
                tempname filesav
                postfile `filesav' pr Sp using results.dta, replace
                local Sp = -1
                local pr = -1
                post `filesav' (`pr') (`Sp')
                postclose `filesav'
        end

Change the

        post `filesav' (`pr') (`Sp')

to

        post `filesav' `pr' `Sp'

and the program stops working.