Bookmark and Share

Notice: On April 23, 2014, Statalist moved from an email list to a forum, based at

[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]

Re: st: main effect insignificant, interaction term significant

From   Maarten buis <>
Subject   Re: st: main effect insignificant, interaction term significant
Date   Wed, 16 Feb 2011 17:21:39 +0000 (GMT)

--- On Wed, 16/2/11, Gáti Annamária wrote:
> Do (and if so, how do) we interpret interaction terms in
> the following  regression example:
> we want to explain whether someone got lung cancer or not
> and we explain this by gender and smoking.
> gender= non sign.
> ever smoked= non sign.
> gender*smoked= sign

One strategy is to reformulate your model so that you 
directly see the effect of ever_smoked for men and for

Consider the example below, which I think is similar 
to your problem (black and white would be male and 
female in your problem; collgrad would be ever_smoked
in your problem; and union membership would be equivalent
to lung cancer in your problem). 

In the group white women without college degree you 
would expect .24 union members for every non-union member
(the baseline odds). This odds is 1.56 times higher for
black women. 

The odds of unionmembership increases by a factor 1.89
when black women get a college degree and by a factor
1.70 when white women get a college degree. In the 
example below the difference in these effects are non-
significant, but in your case that difference will be

*-------------------- begin example ---------------------
sysuse nlsw88, clear
drop if race == 3 // drop "others"

// I think that it is informative to make the 
// interaction terms yourself:

// race would be gender in your model
// you would make the variables male and female instead
gen byte black = race == 2 if !missing(race)
gen byte white = race == 1 if !missing(race)

// collgrad would be never_smoked in your model
gen byte blackXcoll = black*collgrad
gen byte whiteXcoll = white*collgrad

gen byte baseline = 1

logit union black blackXcoll whiteXcoll baseline, nocons or

// if we want to test whether the effect of
// collgrad is the same for black and white women
// we can either estimate your model and look at
// the significance of the interaction term or:

test blackXcoll = whiteXcoll

// However, you can also use Stata's new factor
// variable notation:

logit union i.race i.race#i.collgrad baseline, nocons or
*--------------------- end example ----------------------------
(For more on examples I sent to the Statalist see: )

Hope this helps,

Maarten L. Buis
Institut fuer Soziologie
Universitaet Tuebingen
Wilhelmstrasse 36
72074 Tuebingen


*   For searches and help try:

© Copyright 1996–2018 StataCorp LLC   |   Terms of use   |   Privacy   |   Contact us   |   Site index