# RE: st: Confidence Interval for Proportion

 From Maarten buis To statalist@hsphsun2.harvard.edu Subject RE: st: Confidence Interval for Proportion Date Tue, 11 Mar 2008 19:55:25 +0000 (GMT)

```Jeff said that -proportion- treats the proportion as a mean, and
reports the results of a t-test. So using trick from (Buis 2007), you
can, in the example below, exactly (no pun intended) reproduce the
confidence interval.

*----------------------- begin example ----------------------
sysuse auto, clear
proportion rep78

// reproduce the standard error
local se = sqrt([rep78]_b[1]*(1-[rep78]_b[1])/(e(N)-1))
di `se'

// reproduce the conf. int.
local lb = [rep78]_b[1] - invttail(`e(df_r)', .025) * `se'
local ub = [rep78]_b[1] + invttail(`e(df_r)', .025) * `se'
di `lb'
di `ub'
*-------------------- end example ----------------------------
(For more on how to use examples I sent to the Statalist, see
http://home.fsw.vu.nl/m.buis/stata/exampleFAQ.html )

M.L. Buis (2007), "Stata tip 54: Where did my p-values go?", The Stata
http://home.fsw.vu.nl/m.buis/wp/pvalue.html

Hope this helps,
Maarten

--- Martin Weiss <martin.weiss@uni-tuebingen.de> wrote:

> Jeff,
>
> thanks for the reply, but am I still missing something here? I did
> experiment with the " r(N)-1", but discarded the possibility as it
> did not
> provide the correct lower and upper bound... Indeed,
>
> ************************
> sysuse auto, clear
> proportion rep78
> matrix define A=e(b)
> count if rep78!=.
> *Std error
> local stderr= sqrt(A[1,1]*(1-A[1,1])/`=`r(N)'-1')
> *Upper/Lower Bound for proportion of "1"
> di A[1,1]+invnormal(1-0.05/2)*`stderr'
> di A[1,1]-invnormal(1-0.05/2)*`stderr'
> ************************
>
> still gives the wrong numbers. Have you told us the whole story?
>
> Martin Weiss
> _________________________________________________________________
>
> Diplom-Kaufmann Martin Weiss
> Mohlstrasse 36
> Room 415
> 72074 Tuebingen
> Germany
>
> Fon: 0049-7071-2978184
>
> Home: http://www.wiwi.uni-tuebingen.de/cms/index.php?id=1130
>
> Publications: http://www.wiwi.uni-tuebingen.de/cms/index.php?id=1131
>
> SSRN: http://papers.ssrn.com/sol3/cf_dev/AbsByAuth.cfm?per_id=669945
>
>
> -----Original Message-----
> From: owner-statalist@hsphsun2.harvard.edu
> [mailto:owner-statalist@hsphsun2.harvard.edu] On Behalf Of Jeff
> StataCorp LP
> Sent: Tuesday, March 11, 2008 7:08 PM
> To: statalist@hsphsun2.harvard.edu
> Subject: Re: st: Confidence Interval for Proportion
>
> Martin Weiss <martin.weiss@uni-tuebingen.de> is using the
> -proportion-
> command
> and has a question about how standard errors are computed:
>
> > Dear Statalisters,
> >
> > try this in Stata:
> >
> > ************************
> > sysuse auto, clear
> > proportion rep78
> > matrix define A=e(b)
> > matrix define B=e(V)
> > count if rep78!=.
> > *Upper/Lower Bound for proportion of "1"
> > di A[1,1]+invnormal(1-0.05/2)*sqrt(A[1,1]*(1-A[1,1])/`r(N)')
> > di A[1,1]-invnormal(1-0.05/2)*sqrt(A[1,1]*(1-A[1,1])/`r(N)')
> > *Standard Error for "1"
> > *Mistake obviously there...
> > di sqrt(A[1,1]*(1-A[1,1])/`r(N)')
> > ************************
> >
> > Then let me know: why do I not hit the correct CI for the
> proportion of
> "1"
> > in the repair record? Something`s wrong with the standard error, I
> do not
> > know what, though...
>
> Using Martin's example Stata code, -proportion- effectively computes
> the
> standard error via
>
> 	sqrt(A[1,1]*(1-A[1,1])/(r(N)-1))
>
> This is explained (rather tersely, I'll admit) in the 'Methods and
> Formulas'
> section of -[R] proportion-.
>
> 	"Proportions are means of indicator variables; see -[R] mean-."
>
> From the 'Methods and Formulas' section of -[R] mean-, the variance
> is
> calculated as
>
> 	V(ybar) = (1/(N*(N-1))) Sum_{j=1}^N (y_j - ybar)^2
>
> If the y_j are observations of an indicator variable, this is
> algebraically
> equivalent to
>
> 	V(ybar) = ybar(1-ybar)/(N-1)
>
> --Jeff
> *
> *   For searches and help try:
> *   http://www.stata.com/support/faqs/res/findit.html
> *   http://www.stata.com/support/statalist/faq
> *   http://www.ats.ucla.edu/stat/stata/
>
> *
> *   For searches and help try:
> *   http://www.stata.com/support/faqs/res/findit.html
> *   http://www.stata.com/support/statalist/faq
> *   http://www.ats.ucla.edu/stat/stata/
>

-----------------------------------------
Maarten L. Buis
Department of Social Research Methodology
Vrije Universiteit Amsterdam
Boelelaan 1081
1081 HV Amsterdam
The Netherlands

Buitenveldertselaan 3 (Metropolitan), room Z434

+31 20 5986715

http://home.fsw.vu.nl/m.buis/
-----------------------------------------

___________________________________________________________
Rise to the challenge for Sport Relief with Yahoo! For Good

http://uk.promotions.yahoo.com/forgood/
*
*   For searches and help try:
*   http://www.stata.com/support/faqs/res/findit.html
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/
```