There _is_ scope for graphing the contents of a local.
The following code shows some technique.
local x = 1
foreach num of numlist 90 95 99 99.5 99.9 99.99{
cii 12 0, level(`num')
local plot `plot' `r(ub)' `x'
local label `label' `x' "`num'"
local ++x
}
twoway scatteri `plot', recast(line) xla(`label') ///
ytitle(upper bound) xtitle(level)
Nick
[email protected]
Maarten buis
--- Martin Weiss <[email protected]> wrote:
> If I want to graph the development of the upper bound of a binomial
> ci, as in:
>
> local ub
>
> foreach num of numlist 90 95 99 99.5 99.9 99.99{
> cii 12 0, level(`num')
> local ub `ub' `r(ub)'
> }
>
> tempvar ra
> range `ra' 1 6
>
> line `ub' `ra'
>
> how do I get Stata to recognize the contents of the local for the
> line graph?
You can't. You can create a "data file" with the upper bounds and plot
that:
*------------------------- begin example ------------------
drop _all
input alpha
90
95
99
99.5
99.9
99.99
end
gen ub = .
local i = 1
foreach num of numlist 90 95 99 99.5 99.9 99.99 {
cii 12 0, level(`num')
replace ub = `r(ub)' in `i++'
}
line ub alpha
*------------------- end example --------------------
(For more on how to use examples I sent to the Statalist, see
http://home.fsw.vu.nl/m.buis/stata/exampleFAQ.html )
*
* For searches and help try:
* http://www.stata.com/support/faqs/res/findit.html
* http://www.stata.com/support/statalist/faq
* http://www.ats.ucla.edu/stat/stata/
