Re: st: SEM: cannot correlate exogenous variable with endogenous variable

[jpitblado@stata.com (Jeff Pitblado, StataCorp LP)]

Jeremy Reynolds <jeremyr@uga.edu> is using -sem- and is having trouble
specifying a model that appears to require a covariance between an exogenous
variable and an endogenous variable.

> I am attempting to estimate an SEM model that contains reciprocal
> effects and lagged predictors.  The model is based on the work of Paul
> Allison see:
> 
> http://www.statisticalhorizons.com/wp-content/uploads/2012/01/Causal-Inference.pdf
> (The model is also described on page 1247 of England et al. Social
> Science Research 36: 2007 and in Allison's 2005 book, Fixed Effects
> Regression Models Using SAS.)
> 
> My code is below.  The model I estimate contains measures of
> victimization at 4 points in time (vic1-vic4) and offending at 3
> points in time (off1-off3), as well as a latent variable that measures
> time-invariant fixed effects.
> 
> The problem is that I am not able to specify a correlation between
> off3 and vic2 as specified at the end of the cov option.  Stata
> replies:
> 
> invalid specification of covariance between 'vic2' and 'off3';
>   'vic2' is an observed dependent variable and
>   'off3' is an observed independent variable

Based on a given model specification, -sem- categorizes variables as observed
or latent and endogenous (dependent) or exogenous (independent).  -sem- allows
all exogenous variables to covary, regardless of being latent or observed.
However -sem- does not allow any endogenous variable to directly covary with
any other variable, only regression paths and covariances between their
associated error variables are allowed.  Based on Jeremy's model
specification, -sem- recognized 'vic2' as endogenous.

> This correlation, however, is essential to the model.  Allison writes,
> "the assumption of sequential exogeneity is modelled by allowing the
> error term at each point in time to be correlated with future values
> of the time-dependent covariates, but not past values (Wooldridge
> 2002)."
> 
> It appears that the intended model can be estimated in SAS and MPlus.
> Is Stata not able to to estimate this model?  I am more inclined to
> think that I have made a mistake in specifying the model, but I cannot
> find it.

I believe Jeremy's model can be specified, we merely need to specify the
exogenous variables as dependent variables without any independent predictors,
except an intercept.  In this specification, -sem- will allow any covariance
between the corresponding error variables.

Here is how I modified Jeremy's model

***** BEGIN:
#delimit ;
sem
        (_cons -> off1)
        (_cons -> off2)
        (_cons -> off3)
        (_cons -> vic1)
        (off1@off -> vic2)
        (off2@off -> vic3)
        (off3@off -> vic4)
        (vic1@vic -> vic2)
        (vic2@vic -> vic3)
        (vic3@vic -> vic4)
        (alpha@1 -> vic2)
        (alpha@1 -> vic3)
        (alpha@1 -> vic4)
        (_cons@0 -> alpha)
        ,
        latent(alpha)
        covstr(e.off1 e.off2 e.off3 e.alpha, unstructured)
        cov(
                e.vic2@resid
                e.vic3@resid
                e.vic4@resid
                e.vic1*e.alpha
                e.vic1*e.off1
                e.vic1*e.off2
                e.vic1*e.off3
                e.off3*e.vic2
        )
;
#delimit cr
***** END:

--Jeff
jpitblado@stata.com
*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/faqs/resources/statalist-faq/
*   http://www.ats.ucla.edu/stat/stata/