Bookmark and Share

Notice: On April 23, 2014, Statalist moved from an email list to a forum, based at statalist.org.


[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]

Re: st: Re: comparing regression discontinuity treatment effects for different subsamples


From   Austin Nichols <[email protected]>
To   [email protected]
Subject   Re: st: Re: comparing regression discontinuity treatment effects for different subsamples
Date   Tue, 12 Oct 2010 22:37:00 -0400

John Antonakis <[email protected]>:
Yes, I would still disagree with this characterization. The idea in RD
is to estimate the discontinuity in mean outcomes at a discontinuity
in treatment, allowing the assignment variable to have an arbitrarily
convoluted (but continuous) effect on expected outcomes.  Hence local
linear regression, not regression, and estimated separately on each
side of the discontinuity.  You can use a rectangular kernel, or a
triangle kernel, or what have you, but you should not simply include
the whole sample and constrain the effect of the assignment variable
to be everywhere the same.  The choice of bandwidth is the tuning
parameter trading off bias and variance; if you use only a few
observations on either side of the cutoff, you have low bias because
those observations really are exchangeable, but you have very high
variance estimates; if you use a lot of data on either side of the
cutoff you have lower variance but possibly more bias as well as you
project out to the conditional mean at the cutoff from both sides.
Your proposed approach maximizes bias, in many cases. You are also
implicitly assuming a deterministic assignment to treatment, I think,
rather than a so-called "fuzzy" RD design. If you want to frame it as
a regression, instead of
  g z=pretest-cutoff
  reg y group z
which is your proposal, you might instead do
 g w=max(0,1-abs(z))
 la var w "Triangle kernel weight"
 g a=(z>0)
 la var a "Above cutoff"
 g za=z*a
 reg y a z za [pw=w]
or
 ivreg2 y (group=a) z za [pw=w]
using -ivreg2- from SSC, if group (measuring treatment status) is not
always equal to a.

Compare approaches:
* Note that rd is from SSC;
* rdob from http://www.economics.harvard.edu/faculty/imbens/software_imbens
mat c=(1,.5\.5,1)
set seed 1
drawnorm e pretest, n(1000) corr(c) clear
g z=pretest-0
g above=z>0
g group=cond(uniform()<.8,above,1-above)
g y=z-z^3+group+e
* next is per John Antonakis
reg y z group
g w=max(0,1-abs(z))
g za=z*above
ivreg2 y (group=above) z za [pw=w]
rdob y z, c(0) fuzzy(group)
bs:rd y group z, bw(1)
* now a "sharp" design
mat c=(1,.5\.5,1)
set seed 1
drawnorm e pretest, n(1000) corr(c) clear
g z=pretest-0
g above=z>0
g group=above
g y=z-z^3+group+e
* next is per John Antonakis
reg y z group
g w=max(0,1-abs(z))
g za=z*above
reg y group z za [pw=w]
rdob y z, c(0)
bs:rd y group z, bw(1)


On Tue, Oct 12, 2010 at 5:20 PM, John Antonakis <[email protected]> wrote:
> Hi Austin:
>
> Thanks for this; I was not clear enough. In the following, suppose that
> selection is based on the following explicit rule (where cut-off is at the
> mean of the pretest):
>
> group =1 if pretest of person i is less than or equal to mean of pretest
> group =0 if pretest of person i is greater than pretest
>
> We provide the treatment to group 1, and we estimate:
>
> y = b0 + b1*(pretest - mean pretest) + b2*group + e
>
> Here, b2 is the treatment effect and captures the jump in the discontinuity.
> Thus, constraining b2 to be equal across the two samples captures the
> difference in treatment effects across the two samples--or am I missing out
> on something?
>
> Best,
> J.
>
*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/


© Copyright 1996–2018 StataCorp LLC   |   Terms of use   |   Privacy   |   Contact us   |   Site index