Bookmark and Share

Notice: On April 23, 2014, Statalist moved from an email list to a forum, based at

[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]

Re: st: continuous interactions

From   Maarten buis <[email protected]>
To   [email protected]
Subject   Re: st: continuous interactions
Date   Tue, 5 Oct 2010 08:21:34 +0100 (BST)

--- On Mon, 4/10/10, Erum Ikramullah wrote:
> Does anyone have experience running a continuous X
> continuous interaction in a multinomial regression model? 
> I need some help interpreting the findings. 

Consider the example below:

*----------------- begin example ------------------
sysuse auto, clear

// create an indicator variable that is
// 1 when an observation has valid values
// on mpg, price, and rep78, and 0 otherwise
gen byte touse = !missing(mpg, price, rep78)

// center mpg
sum mpg if touse, meanonly
gen c_mpg = mpg - r(mean)

// center price and change unit to 1000s of $
sum price if touse, meanonly
gen c_price = (price - r(mean))/1000

// see the example FAQ
recode rep78 1/2 = 3
gen byte baseline = 1

// add value labels to rep78
label define rep78 3 "Average" ///
                   4 "Good"    ///
                   5 "Excellent"
label value rep78 rep78

// the model
mlogit rep78 c.c_mpg##c.c_price foreign baseline, rrr nocons
*-------------------- end example --------------------
(For more on examples I sent to the Statalist see: )

When it comes to interactions it is always a good idea to
make sure that the value 0 of each of your variables have
a substantive meaning that could meaningfully occur in the
data. In this case I did that by mean centering my variables.

One way of interpreting -mlogit- model is to look at the 
odds ratios. This has certain advantages when it comes
to interpreting interaction terms, as I discussed in 
Buis (2010).

Assume that we are interested in the effect of mpg and 
how it changes when the price changes. I find it easiest
to start with the baseline odds. The reference are average
cars. In the Good equation we see that for domestic cars
of average mpg and price we expect to find 0.36 good cars 
for every average car. For an average priced car this odds
increases with a factor 1.097 (i.e. 9.7%) for every mile
per gallon increase in mpg. This effect of mpg increases
with a factor 1.058 (i.e. 5.8%) for every 1000$ increase
in price.

In the Excellent equation we see that for domestic cars 
with average price and mpg we expect to find 0.03 Excellent 
cars for every average car. For an averaged priced care this
odds increases with a factor 1.22 (i.e. 22%) for every 
mile per gallon increase in mpg, and this effect decreases
with a factor 0.97 (i.e. -3%) for every 1000$ increase in

Hope this helps,

M.L. Buis (2010) "Stata tip 87: Interpretation of interactions 
in non-linear models", The Stata Journal, 10(2), pp. 305-308.

Maarten L. Buis
Institut fuer Soziologie
Universitaet Tuebingen
Wilhelmstrasse 36
72074 Tuebingen


*   For searches and help try:

© Copyright 1996–2018 StataCorp LLC   |   Terms of use   |   Privacy   |   Contact us   |   Site index