Re: st: Logistic regression interpretation

[Maarten buis <maartenbuis@yahoo.co.uk>]

--- On Wed, 22/9/10, Dr. Bill Westman wrote:
> Also - those two di statements at show the exact same odds
> - was this intentional?

It is important to make a distinction between odds and odds-ratios.
The former is a measure of the likelihood of an event, the latter
is a measure of how this likelihood differs across groups.

So in the example below we first compute the odds of union membership
separately for married and non-married people. Remember that the odds
is the expected number of union members per non-union member, so if 
we observe 10 union members and 20 non-union members then we expect
to see 10/20=.5 union member for every non-union member.

After that we look at how the odds of union membership differs between
married and non-married women, by computing the ratio.

After that I show that that is exactly what -logit- does.

*--------------------------- begin example --------------------------
sysuse nlsw88, clear
tab married union
di "the odds of union membership for married women is: " 280/942
// so there are .30 union members for every non-union member when
// the women is married

di "the odds of union membership for non-married women is: " 181/475
// so there are .38 union members of every non-union member when the 
// women is not married

di "the odds of union membership for married women is " ///
   (280/942)/(181/475)  " times the odds of union membership" ///
   " for non-married women"
// so mariage reduces the odds of memebership with 22%

// this odds ratio can be recovered with -logit-.
logit union married, or

// the odds can be recovered using -margins.
margins , exp(exp(xb())) over(married)
*---------------------- end example ---------------------------------

Hope this helps,
Maarten

--------------------------
Maarten L. Buis
Institut fuer Soziologie
Universitaet Tuebingen
Wilhelmstrasse 36
72074 Tuebingen
Germany

http://www.maartenbuis.nl
--------------------------


      

*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/