[Date Prev][Date Next][Thread Prev][Thread Next][Date index][Thread index]

# Re: st: Marginal effects in (bi)probit models

 From Martin Watts To statalist@hsphsun2.harvard.edu Subject Re: st: Marginal effects in (bi)probit models Date Tue, 18 Mar 2008 07:11:57 +1100

```Thanks very much Austin. I'll have a close look at your email.

Kind regards
Martin

>>> Austin Nichols <austinnichols@gmail.com> 03/18/08 3:58 AM >>>
Martin Watts <Martin.Watts@newcastle.edu.au>:
I can think of a few reasons why your question might have generated no
replies, but my best guess is that it is too ambiguous to spark a
response.  There are a number of kinds of marginal effects that can be
calculated after a probit-type model and myriad ways of estimating
them, but one is to impute two values to the entire sample and
calculate the mean difference in predictions, e.g.

sysuse nlsw88
g cxh=collgr*hours
g cxw=collgr*wage
probit nev collgr wage hours cxh cxw, nolog
preserve
replace collg=1
* Now redefine every variable in which collgr appears:
replace cxh=collgr*hours
replace cxw=collgr*wage
predict p1, p
replace collg=0
replace cxh=collgr*hours
replace cxw=collgr*wage
predict p0, p
g margeff=p1-p0
su margeff
restore

This type of "brute force" approach is always available, and has many
desirable properties.  Conceptually, it is like an Average Treatment
Effect (ATE) estimate, with no matching or reweighting.

To get standard errors, you can wrap the whole thing in a -program-
and bootstrap:

cap prog drop mfcoll
prog mfcoll, eclass
probit nev collgr wage hours cxh cxw, nolog
g samp=e(sample)
preserve
replace collg=1
replace cxh=collgr*hours
replace cxw=collgr*wage
predict p1, p
replace collg=0
replace cxh=collgr*hours
replace cxw=collgr*wage
predict p0, p
g margeff=p1-p0
su margeff
mat b=r(mean)
restore
ereturn post b, es(samp)
end
bs: mfcoll

See also -help adjust- for a different approach.

On Sun, Mar 16, 2008 at 3:54 PM, Martin Watts
<Martin.Watts@newcastle.edu.au> wrote:
> I sent the following msg to the list, but surprisingly got no response. Can anyone assist?
> Thanks.

> >>> Martin Watts <Martin.Watts@newcastle.edu.au> 03/14/08 9:43 AM >>>
> I am aware of the Stata code inteff3 which enables the computation of MEs when there is a triple dummy variable interaction term ie
> b1x1 + b2x2 + b3x3 + b12x1x2+b13x1x3 + b23x2x3 +b123x1x2x3
>
> but I am unaware of code which computes MEs when there is a gender slope dummy attached to a number of independent variables say for a labor force participation equation. Clearly both age and the presence of children are likely to differ in their impact on lfp of women and men.
>
> So MEs would be required say both for the impact of the presence of a young child on female and male lfp, noting that the change in the dummy variable is impacting on the other variables uin the probit eqn too.
>
> Can anyone cast any light on this problem.
>
> Many thanls.
*
*   For searches and help try:
*   http://www.stata.com/support/faqs/res/findit.html
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/

*
*   For searches and help try:
*   http://www.stata.com/support/faqs/res/findit.html
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/
```

 © Copyright 1996–2019 StataCorp LLC   |   Terms of use   |   Privacy   |   Contact us   |   What's new   |   Site index