Statalist


[Date Prev][Date Next][Thread Prev][Thread Next][Date index][Thread index]

Re: st: dprobit and outreg


From   "Austin Nichols" <austinnichols@gmail.com>
To   statalist@hsphsun2.harvard.edu
Subject   Re: st: dprobit and outreg
Date   Tue, 11 Dec 2007 21:30:13 -0500

Alyssa Schneebaum <mail.schnee@gmail.com>:
I can't help you with -outreg-, but the results you want from
-dprobit- are stored in e(dfdx) and e(se_dfdx), not e(b) and e(V).
You could try something like this:

use http://fmwww.bc.edu/ec-p/data/wooldridge/card, clear
loc x "exper* smsa* south mar black reg662-reg669"
g coll=educ>=16
prog drop _all
prog dp, eclass
 dprobit `0'
 loc d: word 1 of `0'
 loc nobs=e(N)
 tempvar s
 g `s'=e(sample)
 mat v=e(se_dfdx)
 mat vv=v'*v
 mat b=e(dfdx)
 eret post b vv, dep(`d') e(`s')
 ereturn local depvar "`d'"
 ereturn scalar N = `nobs'
 ereturn local cmd "dp"
 end
dprobit coll `x' nearc2 nearc4
est sto dprobit
dp coll `x' nearc2 nearc4
est sto dp
ssc inst estout
esttab *, nogaps mti

or just use

ssc inst estout
esttab *, margin

to get the "marginal effects" directly.  Note that these are unlikely
to be of much practical use, as the calculus argument for these being
marginal effects at some level of X often breaks down in practice.
You may want to -findit spost- for more.

On Dec 11, 2007 8:03 PM, Alyssa Schneebaum <mail.schnee@gmail.com> wrote:
> Hello Statalisters,
>
> I am running several dprobit regressions, and then outreg-ing the
> results to an Excel file. However, the coefficients being sent to the
> Excel file are DIFFERENT than what comes up in the Stata output. The
> z-statistics are exactly the same though. Does anyone know what's
> going on?
>
> Thanks for any help,
> Alyssa
*
*   For searches and help try:
*   http://www.stata.com/support/faqs/res/findit.html
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/



© Copyright 1996–2022 StataCorp LLC   |   Terms of use   |   Privacy   |   Contact us   |   What's new   |   Site index