Re: st: Looping with merge

[Nick Cox <njcoxstata@gmail.com>]

It's one loop, not two.

local files zip_pov p15_zip p37_zip
local vars povrate permcf perbachelor

forval i = 1/3 {
     local f : word `i' of `files'
     local v : word `i' of `vars'
     merge m:1 zip_num using `f', keepusing(`v')
     drop if _merge==2
     drop _merge
}

OR

forval i = 1/3 {
     local f : word `i' of zip_pov p15_zip p37_zip
     local v : word `i' of povrate permcf perbachelor
     merge m:1 zip_num using `f', keepusing(`v')
     drop if _merge==2
     drop _merge
}

Nick
njcoxstata@gmail.com


On 13 May 2013 15:42, Adam Guerrero <adamgue@gmail.com> wrote:
> Hello All,
>
> I am trying to write a loop for the following lines of code
>
> merge m:1 zip_num using zip_pov.dta, keepusing(povrate)
> drop if _merge==2
> drop _merge
> merge m:1 zip_num using p15_zip.dta, keepusing(permcf)
> drop if _merge==2
> drop _merge
> merge m:1 zip_num using p37_zip.dta, keepusing(perbachelor)
> drop if _merge==2
> drop _merge
>
> This is what, but has not been working
>
> foreach file in zip_pov.dta p15_zip.dta p37_zip.dta {
> foreach var of varlist "povrate" "permcf" "perbachelor" {
> merge m:1 zip_num using `file', keepusing(`var')
> drop if _merge==2
> drop _merge
>     }
> }
>
*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/faqs/resources/statalist-faq/
*   http://www.ats.ucla.edu/stat/stata/