re: Re: st: growth rate

[Christopher Baum <kit.baum@bc.edu>]

<>
One can do better than any of the suggestions posed when the growth rate is non-infinitesimal, as it may well be over a multi-year span:

clear
input gdp year
100 1995
. 1997
. 2002
. 2007
end

// compute GDP to grow steadily at 5% p.a.
replace gdp = gdp[_n-1] * 1.05^(year - year[_n-1]) in 2/l
g lgdp = log(gdp)

// Nick's suggestion

gen growthN = (lgdp - lgdp[_n-1]) / (year - year[_n-1])

// Kit's suggestion, taking compounding into account,
// avoiding the approximation that ln(1+x) ~ x for small x

g growthK = exp((lgdp - lgdp[_n-1]) / (year - year[_n-1])) - 1
l

. l

     +--------------------------------------------------+
     |      gdp   year       lgdp    growthN    growthK |
     |--------------------------------------------------|
  1. |      100   1995    4.60517          .          . |
  2. |   110.25   1997   4.702751   .0487902   .0500001 |
  3. |   140.71   2002   4.946702   .0487902        .05 |
  4. | 179.5856   2007   5.190652   .0487902        .05 |
     +--------------------------------------------------+

Kit

Kit Baum   |   Boston College Economics & DIW Berlin   |   http://ideas.repec.org/e/pba1.html
                             An Introduction to Stata Programming  |   http://www.stata-press.com/books/isp.html
  An Introduction to Modern Econometrics Using Stata  |   http://www.stata-press.com/books/imeus.html


*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/faqs/resources/statalist-faq/
*   http://www.ats.ucla.edu/stat/stata/