Bookmark and Share

Notice: On April 23, 2014, Statalist moved from an email list to a forum, based at

[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]

Re: st: Interpreting Coefficient of a count independent variable

From   Maarten Buis <>
Subject   Re: st: Interpreting Coefficient of a count independent variable
Date   Mon, 16 Apr 2012 10:18:05 +0200

On Mon, Apr 16, 2012 at 7:24 AM, Muhammad Anees wrote:
> I am trying to figure out how smoking affects earnings contradictory
> to the normal routine of studying the affects of earnings on smoking
> in my previous studies.
> I have run the following result and I want to know the possible
> interpretational issues with a count independent variables.

None, other than the usual caveat that the effects may not be linear.
I typically start with  a -glm- with the log link for a variable like
income. I would than try adding an extra indicator variable for
non-smokers as these are in all likelihood very different the rest of
the curve. After that I would try various linear splines to capture
any additional non-linearity. Consider the example below:

*----------------- begin example -------------------
sysuse nlsw88, clear

gen c_hours = hours - 40
mkspline t40 0 mt40 = c_hours
gen byte normal = hours == 40 if hours < .

gen marst = !never_married + 2*married
label var marst "marital status"
label define marst 0 "never married"    ///
                   1 "widowed/divorced" ///
                   2 "married"
label value marst marst

gen c_grade = grade - 12
glm wage t40 mt40 normal c_grade i.race i.marst ///
    c.ttl_exp##c.ttl_exp c.tenure##c.tenure     ///
    , link(log) eform

replace c_grade = 0
replace race = 1
replace marst = 0
replace ttl_exp	= 0
replace tenure = 0

bys hours : keep if _n == 1

predict yhat, mu

twoway line yhat hours
*------------------ end example --------------------

I would interpret these results as follows: If someone works less than
40 hours a week her hourly wage will increase by (1-1.02)*100%=2% for
every hour extra worked. There is a sudden (but non-significant) drop
in this curve at 40 hours of (1-.98)*100%= -2%. After 40 hours a week
the hourly wage will drop a non-significant 1% per hour extra worked.

This story is also shown in the graph. I guess that it should also be
possible to also do this with -margins- and -marginsplot-, but I was
unsuccessful, so I fell back to old and trusted -predict- solution.

Hope this helps,

Maarten L. Buis
Institut fuer Soziologie
Universitaet Tuebingen
Wilhelmstrasse 36
72074 Tuebingen
*   For searches and help try:

© Copyright 1996–2018 StataCorp LLC   |   Terms of use   |   Privacy   |   Contact us   |   Site index