Re: st: scatter plot with lines laid on

[Maarten buis <maartenbuis@yahoo.co.uk>]

--- On Mon, 21/3/11, Jian Zhang wrote:
> Hi all, I was graphing a scatter plot with a number of
> values for x in the x-axis.  What I'd like to do is to lay
> on the scatter plot three lines: one line connecting the
> means of y at each value of x and two lines connecting the
> one standard deviation above and below the means of y at
> each value of x, respectively. Does anyone know how to do
> this?  

What about this:

*--------------- begin example --------------
sysuse auto, clear

bys rep78: egen m = mean(price)
bys rep78: egen sd = sd(price)
gen lb = m - sd
gen ub = m + sd

twoway rarea lb ub rep78, astyle(ci) || ///
       line m rep78, lstyle(p1)      || ///
       scatter price rep78, msymbol(Oh) 
*-------------- end example -----------------
(For more on examples I sent to the Statalist see: 
http://www.maartenbuis.nl/example_faq )

Hope this helps,
Maarten

--------------------------
Maarten L. Buis
Institut fuer Soziologie
Universitaet Tuebingen
Wilhelmstrasse 36
72074 Tuebingen
Germany

http://www.maartenbuis.nl
--------------------------


      

*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/