Re: st: Suest v/s biprob in stata 11

[Prakash Kashwan <pkashwan@umail.iu.edu>]

Thanks so much, Maarten,
I think you may have understood my problem differently than I did.


"All that is necesary is that your model for the mean(s) is/are
correct. ......... You want the p-values of both test to be uniformly
distributed
as they test an hypothesis that is true in the population"

I am conducting the two tests on same set of observations (so, the
population is not divided into two groups). Moreover, in my case, I am
using the same set of independent variables to estimate probabilities
for two different dependent variables, and after I have run the
'suest' command, I would like to figure out if the suest, did find
significant correlation between the two error matrices, and if it
makes sense for me to use suest in this case.

Many Thanks again in advance,
Prakash

On Mon, Jul 5, 2010 at 9:56 AM, Maarten buis <maartenbuis@yahoo.co.uk> wrote:
> --- On Mon, 5/7/10, Prakash Kashwan wrote:
>> From your explanation it seems as if biprob accounts for
>> the correlation between the residuals from constituent
>> models while suest does not. Am I interpreting it well?
>
> Yes
>
>> If this is indeed the case, it is problematic because the
>> way stata runs it, suest is a postestimation command,
>> which is supposed to look for correlation between the
>> residuals. Am I to assume that suest is not doing what it
>> is supposed to do, and I should use biprob instead of
>> using suest?  What purpose does suest (as post-estimation
>> command) serve then?
>
> The way I understand this is that the inference takes this
> correlation into account in a way that is similar to the
> way -robust- standard errors take heteroskedasticity into
> acount without estimating the changing error variance.
> All that is necesary is that your model for the mean(s) is/are
> correct. You can see that in the simulation below. You
> want the p-values of both test to be uniformly distributed
> as they test an hypothesis that is true in the population,
> as is discussed in this post:
> <http://www.stata.com/statalist/archive/2010-06/msg01191.html>
>
> *----------------- begin example -----------------
> matrix C = (1, .25 \ .25, 1)
>
> program drop _all
> program sim, rclass
>        drop _all
>
>        drawnorm e1 e2, n(1000) corr(C)
>        gen x = rnormal()
>
>        gen y1=  ( x + e1) > 0
>        gen y2 = (-x + e2) > 0
>
>        probit y1 x
>        est store a
>        probit y2 x
>        est store b
>
>        suest a b
>        test [a_y1]x = - [b_y2]x
>        return scalar p_suest = r(p)
>
>        biprobit y1 y2 = x
>        test [y1]x = -[y2]x
>        return scalar p_biprobit = r(p)
> end
>
> set seed 12345
> simulate p_biprobit = r(p_biprobit) ///
>         p_suest    = r(p_suest),   ///
>         reps(10000) : sim
>
> hangroot p_suest,                   ///
>         dist(uniform) par(0 1)     ///
>         susp notheor ci
>
> hangroot p_biprobit,                ///
>         dist(uniform) par(0 1)     ///
>         susp notheor ci
> *------------------ end example ----------------
> (For more on examples I sent to the Statalist see:
> http://www.maartenbuis.nl/example_faq )
>
> This example requires -hangroot-, which you can download
> by typing in Stata -ssc install hangroot-.
>
> Hope this helps,
> Maarten
>
> --------------------------
> Maarten L. Buis
> Institut fuer Soziologie
> Universitaet Tuebingen
> Wilhelmstrasse 36
> 72074 Tuebingen
> Germany
>
> http://www.maartenbuis.nl
> --------------------------
>
>
>
>
> *
> *   For searches and help try:
> *   http://www.stata.com/help.cgi?search
> *   http://www.stata.com/support/statalist/faq
> *   http://www.ats.ucla.edu/stat/stata/
>



-- 
-- 
Prakash Kashwan <http://mypage.iu.edu/~pkashwan/>
School of Public & Environmental Affairs (SPEA)
Workshop in Political Theory and Policy Analysis; Indiana University,
Bloomington
Research Fellow (2009) - International Foundation for Science (Sweden)

*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/