eststo clear
sysuse auto, clear
bs: reg mpg weight gear foreign
mat se_bs = e(se)
reg mpg weight gear foreign
estadd matrix se_bs
esttab, cell(b se(par) se_bs(par([ ])))
The -cells()- option is documented in -help estout-. Specifying
-cells()- in -esttab- disables some of -esttab-'s defaults such as the
numeric formats. So you may want to add further suboptions in the
-cells()- call. Example:
estout, cell(b(fmt(a3)) se(par) se_bs(par([ ])))
ben
On Tue, Aug 5, 2008 at 6:22 PM, Martin Weiss
<[email protected]> wrote:
> Dear Statalisters,
>
> is it possible to have two standard errors per covariate below the point
> estimate in -ssc d estout-? I wanted to place the bootstrapped se below the
> analytic ones. So far, I have to report two columns of point estimates as in
>
>
> ********
> cap ssc inst estout
>
> clear*
> sysuse auto, clear
> reg mpg weight gear foreign
> eststo
> bs: reg mpg weight gear foreign
> eststo
> esttab, mtitles(OLS "OLS boot")
> ********
>
> Is there a trick to make this feasible?
>
> Best,
> Martin
> _________________________________________________________________
>
> Diplom-Kaufmann Martin Weiss
> Mohlstrasse 36
> Room 415
> 72074 Tuebingen
> Germany
>
> Fon: 0049-7071-2978184
>
> Home: http://www.wiwi.uni-tuebingen.de/cms/index.php?id=1130
>
> Publications: http://www.wiwi.uni-tuebingen.de/cms/index.php?id=1131
>
> SSRN: http://papers.ssrn.com/sol3/cf_dev/AbsByAuth.cfm?per_id=669945
>
>
> *
> * For searches and help try:
> * http://www.stata.com/help.cgi?search
> * http://www.stata.com/support/statalist/faq
> * http://www.ats.ucla.edu/stat/stata/
>
*
* For searches and help try:
* http://www.stata.com/help.cgi?search
* http://www.stata.com/support/statalist/faq
* http://www.ats.ucla.edu/stat/stata/
