Stata The Stata listserver
[Date Prev][Date Next][Thread Prev][Thread Next][Date index][Thread index]

Re: st: Re: St: Slow STATA

From   Joseph Coveney <[email protected]>
To   Statalist <[email protected]>
Subject   Re: st: Re: St: Slow STATA
Date   Tue, 19 Oct 2004 13:40:34 +0900

Joseph Wagner has problems using -tabulate, exact- with an ordered
categorical dataset and Richard Williams reminded that alternatives are
available for this type of data.

Both variables in the table are at least ordinal in this latest case.
Someday, StataCorp might incorporate into -tabulate- a procedure analogous
to SAS's PROC FREQ with the CMH option, which would nonparametrically handle
ordinal-by-ordinal datasets like this one.  In the meantime, you can use
parametric modeling with  John Hendrickx's -desmat- and look at the linear

Joseph Coveney

set more off
input str5 age byte cou5 byte cou4 byte cou3 byte cou2 byte cou1
     "65-70"        29         41         44          3          0
     "70-74"        20         50         45          5          1
     "74-78"        19         44         51          7          0
     "78-95"         9         38         56         12          0
reshape long cou, i(age) j(sco)
label define Score 5 Excellent 4 "Very Good" 3 Good 2 Fair 1 Poor
label values sco Score
label variable sco Status
label variable age "Age Group"
tabulate age sco [fweight=cou], taub gamma
xi: ologit sco i.age [fweight=cou], or nolog
encode age, generate(sag) label(Age)
char sag[pzat] orp(3)
* You can restrict the contrast to just the linear component
* by stating -orp(1)- in the line above.
desmat: ologit sco sag [fweight=cou], desrep(exp all) verbose or nolog
* Or use one of Stata's alternatives to proportional odds ordinal logistic
* regression (-gologit-, -mclest-, -ocratio-, -rc2-, -sneop-, -soreg-)
* as warranted by theory, preference or circumstance

*   For searches and help try:

© Copyright 1996–2024 StataCorp LLC   |   Terms of use   |   Privacy   |   Contact us   |   What's new   |   Site index