David Airey posted last week:
----------------------------------------------------------------------------
> OK, let me ask a simpler question: can one have baseline covariates in
> within-subjects ANOVAs like we have in ANCOVAs, which are
> between-subject ANOVAs but with covariates?
Just to close out my thread, I asked if the ANOVA options, continuous()
and repeated(), could be used in a repeated measures ANCOVA, a model
discussed by Winer from looking at the online TOC. Stata's response was
that I look at MANOVA instead. So I guess not, but good enough.
----------------------------------------------------------------------------
I believe that you *can* use the -continouous()- and -repeated()- options
together. With involved models, you might need to explicitly specify the
between-subjects error term using the -bse()- option, but that's not any
impediment. I've illustrated their combined use in the do-file below using
the two repeated-measures ANCOVA examples from Chapter 10 of B. J. Winer,
D. R. Brown & K. M. Michels, _Statistical Principles in Experimental Design_
3rd Edition. (NY: McGraw-Hill, 1991), pp. 820-36. The first example has a
single time-invariate covariate for each individual; the second has a
time-varying covariate (i.e., the covariate has a different value at each
repeated measurement). Note that the two examples in Winer, Brown & Michels
don't need the -repeated()- option, since they both have only two
observations.
I'm not sure why Stata Corp. recommended considering -manova- to David, but
perhaps it's because of the admonition stated in the preface to the
repeated-measures ANCOVA section from Winer, Brown & Michels (Section 10.5,
p. 820), "In the behavioral sciences area, the covariance matrix for the
repeated measures is very likely to be more complicated than the
corresponding covariance structure assumed for the usual split-plot design
[in agricultural research]." David's original posting related to the area
of schizophrenia and sensorimotor inhibition.
Joseph Coveney
----------------------------------------------------------------------------
clear
set more off
*
* Table 10.34 on Page 829 (single covariate for all observations)
*
input byte a byte x byte y1 byte y2
1 3 5 8
1 5 15 12
1 8 20 14
1 2 12 6
2 1 15 10
2 8 25 20
2 10 20 15
2 2 15 10
end
generate byte individual = _n
* Note that Table 10.34 has a typographical error, which is corrected below.
replace y1 = 10 in 1
reshape long y, i(individual) j(b)
* ANOVA table (Table 10.35 top, p. 830; note rounding errors in the book)
anova y a / individual | a b a*b
* ANCOVA table (Table 10.35 bottom)
anova y x a / individual | a b a*b, continuous(x) repeated(b)
*
* Table 10.36 on Page 833 (distinct covariate value for each observation)
*
clear
input byte a byte x1 byte y1 byte x2 byte y2
1 3 8 4 14
1 5 11 9 18
1 11 16 14 22
2 2 6 1 8
2 8 12 9 14
2 10 9 9 10
3 7 10 4 10
3 8 14 10 18
3 9 15 12 22
end
generate byte individual = _n
egen byte x_sum = rsum(x1 x2)
reshape long x y, i(individual) j(b)
* ANOVA table (Table 10.37)
anova y a / individual | a b a*b
* ANCOVA table (Table 10.38) Here, Stata balks if -bse()- isn't specified.
anova y x_sum a / individual | a x b a*b, continuous(x x_sum) ///
repeated(b) bse(individual | a)
exit
*
* For searches and help try:
* http://www.stata.com/support/faqs/res/findit.html
* http://www.stata.com/support/statalist/faq
* http://www.ats.ucla.edu/stat/stata/
