Bookmark and Share

Notice: On April 23, 2014, Statalist moved from an email list to a forum, based at statalist.org.


[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]

Re: st: Producing e a two phase single-case graph


From   Joerg Luedicke <[email protected]>
To   [email protected]
Subject   Re: st: Producing e a two phase single-case graph
Date   Sun, 24 Mar 2013 19:05:58 -0400

Do you have something like this in mind?

*------------------------------
// Pre/post toy data
clear
set obs 20
gen prepost = 0 in 1/10
replace prepost = 1 in 11/20
gen time = _n
gen out = 2+runiform() if prepost == 0
replace out = 3+runiform() if prepost

// Fitted values
reg out time if prepost == 0
predict fitpre if e(sample)
reg out time if prepost
predict fitpost if e(sample)

// Plot
line out time if prepost == 0 || ///
line out time if prepost || ///
line fitpre time  || ///
line fitpost time , ///
xline(10.5) ///
ylabel(1(1)4) ///
xlabel(1(1)20, labsize(small)) ///
legend(order(1 "Observed pre" 2 "Observed post" ///
3 "Fitted pre" 4 "Fitted post"))
*------------------------------

Joerg


On Sun, Mar 24, 2013 at 4:34 PM, Dan Brossart <[email protected]> wrote:
> Dear All,
>
> I am trying to generate a graph for single-case data (20 time points total)
> where the baseline has 10 occasions of measurement and the treatment phase
> has 10 occasions of measurement. I need to be able to graph the baseline and
> treatment as a single graph with a vertical line separating the two phases.
> In each phase I need to have a line connecting each data point (but not from
> phase 1 to phase 2). I also need the ability to add a regression line to
> each phase - each phase gets its own line, independent of the other phase
> regression line.
>
> I've looked through Mitchell's "A Visual Guide to Stata Graphics" 3rd Ed.,
> but there isn't an example like this and so far I haven't found anything
> like this in the archives. My efforts to use twoway have so far failed to
> produce anything close. Using twoway with xrescale and a by statement gives
> me two separate graphs and I really want to do this in a single graph.
> Ideas?
>
> Thanks,
>
> Dan
> *
> *   For searches and help try:
> *   http://www.stata.com/help.cgi?search
> *   http://www.stata.com/support/faqs/resources/statalist-faq/
> *   http://www.ats.ucla.edu/stat/stata/
*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/faqs/resources/statalist-faq/
*   http://www.ats.ucla.edu/stat/stata/


© Copyright 1996–2018 StataCorp LLC   |   Terms of use   |   Privacy   |   Contact us   |   Site index