Bookmark and Share

Notice: On March 31, it was announced that Statalist is moving from an email list to a forum. The old list will shut down at the end of May, and its replacement, statalist.org is already up and running.


[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]

Re: st: Dfbeta in Cox regression post-estimation with Stata 10.1


From   Steve Samuels <sjsamuels@gmail.com>
To   statalist@hsphsun2.harvard.edu
Subject   Re: st: Dfbeta in Cox regression post-estimation with Stata 10.1
Date   Thu, 15 Mar 2012 17:39:41 -0400

This email apparently didn't make it to the list and I didn't get a bounce-back. It ends a thread begun February 26.

Steve


Here's a version that works with an arbitrary number of predictors.


*************CODE BEGINS*************
version 10

sysuse auto, clear
stset length

local xvars  turn price

jackknife _b, keep: stcox `xvars', nohr

stcox `xvars', nohr

foreach z of varlist `xvars'{
gen dfb_`z' = ///
(1/_se[`z'])* (_b_`z'-_b[`z'])/(e(N_sub)-1)
}

sum dfb*
***********CODE ENDS*******************


Steve
sjsamuels@gmail.com

On Feb 26, 2012, at 9:47 AM, Steve Samuels wrote:



Use -jackknife- to calculate dfbeta from first principles:

b_i = coefficient, omitting observation i from analysis:

Jackknife Pseudo-value : v_i = n*b - (n-1)*b_i

dfbeta_i = (b - b_i)/se(b)

   = (v_i - b)/(se(b)*(n-1))

This is a direct calculation. The values issued by
later versions of Stata after -stcox- are approximations.

*************CODE BEGINS*************
sysuse auto, clear
stset length

version 10

jackknife _b[turn] , keep: stcox turn
stcox turn
gen  dfbjack1 =  ///
(1/(_se[turn])*(_jk_1 - _b[turn])/(e(N)-1))

version 12.1

stcox turn
predict  dfbcox* ,dfbeta
corr dfb*

**************CODE ENDS**************

Steve
sjsamuels@gmail.com


On Feb 25, 2012, at 6:57 AM, Annibale Cois wrote:

I need to calculate dfbeta statistics for Cox proportional Hazard
Models. Stata 10 does not allow directly to calculate them (Stata 11
does, conversely).
Does anyone know if there is a way to do the same (indirectly) in Stata 10?

Thanks for any help!

Annibale Cois
UCT School Of Public Health
(Master Student)
*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/



*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/


© Copyright 1996–2014 StataCorp LP   |   Terms of use   |   Privacy   |   Contact us   |   Site index