Statalist


[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]

RE: st: curvilinearity with moderator


From   Maarten buis <maartenbuis@yahoo.co.uk>
To   stata list <statalist@hsphsun2.harvard.edu>
Subject   RE: st: curvilinearity with moderator
Date   Wed, 21 Oct 2009 11:55:35 +0000 (GMT)

--- Pat wrote:
> I am trying to examine the moderating effects on a curvilinear 
> relation between variable A and B in a multiple regression,
> 
> ie. 
> 
> A ->B : positive coeff.
> A^2 ->B : negative coefficient
>
> I want to examine whether introducing variable C shifts the 
> whole distribution of A to the right.

It is so easy to get these things wrong, that the safest way 
to interpret these is to plot the effects. Moreover, even if
you get it right, the resulting text you would have to write
to explain it is likely going to be very hard for your reader,
while a graph, like in the example below, is likely to be much
easier to understand.

*---------------- begin example -------------------------
sysuse nlsw88, clear
sum ttl_exp
gen z_ttl_exp = (ttl_exp - r(mean))/r(sd)
gen z_ttl_exp2 = z_ttl_exp^2

gen z_ttl_expXunion = union*z_ttl_exp
gen z_ttl_exp2Xunion = union*z_ttl_exp2

reg wage z_ttl* union grade
qui adjust grade, by(ttl_exp union) gen(wage_hat)
sort union ttl_exp
twoway line wage_hat ttl_exp if union == 0 ||          ///
       line wage_hat ttl_exp if union == 1,            ///
       ytitle("expected wage")                         ///
       note("for a respondent with average education") ///
       legend(order( 1 "non-union"                     ///
                     2 "union")) 
*---------------------- end example -----------------------
(For more on examples I sent to the Statalist see:
http://www.maartenbuis.nl/example_faq )

Hope this helps,
Maarten

--------------------------
Maarten L. Buis
Institut fuer Soziologie
Universitaet Tuebingen
Wilhelmstrasse 36
72074 Tuebingen
Germany

http://www.maartenbuis.nl
--------------------------


      

*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/



© Copyright 1996–2014 StataCorp LP   |   Terms of use   |   Privacy   |   Contact us   |   What's new   |   Site index