Bookmark and Share

Notice: On March 31, it was announced that Statalist is moving from an email list to a forum. The old list will shut down on April 23, and its replacement, statalist.org is already up and running.


[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]

Re: st: Stata journal paper on interaction terms in count models


From   Maarten Buis <maartenlbuis@gmail.com>
To   statalist@hsphsun2.harvard.edu
Subject   Re: st: Stata journal paper on interaction terms in count models
Date   Wed, 8 May 2013 09:46:21 +0200

On Wed, May 8, 2013 at 8:10 AM, James Bernard wrote:
> Norton, Wang and Ai (2004) have discussed a Stat command to test for
> interaction term in Logit models. This could be pretty handy in
> difference-in-difference models where one needs to include an
> interaction term involving treatment and time indicators.
>
> May I check with you if you know of similar commands for testing for
> interaction effects in Poisson/negative binomial models? I would need
> to build a difference-in-difference model in a Poisson model.

There is no need for such a command as you can interpret the
exponentiated coefficient in a poisson or negative binomial model as a
ratio of ratios. Take the example below: In this case we expect that
women with a "good" (managerial or professional) job but not in a
union earn (1.35 - 1)*100% = 35% more than similar women with a "bad"
job while adjusting for race, place of residence, education and
experience. This effect of a good job is (1-.81)*100%= -19% smaller
for union jobs. This is the interaction effect.

*------------------ begin example ------------------
sysuse nlsw88, clear

gen byte black = race == 2 if race < 3
label variable black "race"
label define black 0 "white" ///
                   1 "black"
label value black black

gen byte goodjob = occupation < 3 if occupation < .
label variable goodjob `"respondent has a "good" job"'
label define goodjob 1 "profesional or managerial" ///
                     0 "other"
label value goodjob goodjob

glm wage i.goodjob##i.union i.black south grade ///
    c.ttl_exp##c.ttl_exp,                       ///
    link(log) family(poisson) vce(robust) eform
*------------------- end example -------------------
(For more on examples I sent to the Statalist see:
http://www.maartenbuis.nl/example_faq )

This way of interpreting your interaction term is simple enough and
avoids a whole lot of problems associated with the Norton, Wang and Ai
approach, and preventing problems is always better than trying to cure
them afterwards. In essence the Norton, Wang, and Ai approach tries to
get the marginal effect of an interaction effect, and most people who
use marginal effects (not Norton, Wang and Ai though) want to report 1
marginal effect per variable or interaction term and not as many
effects as there are observations. This is understandable, as a model
is supposed to simplify reality and N different effects for each
variable is not much of a simplification. However, if you report just
one marginal effect you are in essence estimating a linear model on
top of your non-linear model. If that is really what you want then you
should do this in one go and estimate a simple linear regression (and
live with the consequences...).

Hope this helps,
Maarten

---------------------------------
Maarten L. Buis
WZB
Reichpietschufer 50
10785 Berlin
Germany

http://www.maartenbuis.nl
---------------------------------
*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/faqs/resources/statalist-faq/
*   http://www.ats.ucla.edu/stat/stata/


© Copyright 1996–2014 StataCorp LP   |   Terms of use   |   Privacy   |   Contact us   |   Site index