Bookmark and Share

Notice: On March 31, it was announced that Statalist is moving from an email list to a forum. The old list will shut down on April 23, and its replacement, statalist.org is already up and running.


[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]

RE: st: Accuracy table after mlogit


From   <N.M.Postel-Vinay@lse.ac.uk>
To   <statalist@hsphsun2.harvard.edu>
Subject   RE: st: Accuracy table after mlogit
Date   Wed, 27 Jul 2011 10:08:21 +0100

Great. Thanks very much for this.

Natacha


-----Original Message-----
From: owner-statalist@hsphsun2.harvard.edu on behalf of tzygmund mcfarlane
Sent: Tue 26/07/2011 18:22
To: statalist@hsphsun2.harvard.edu
Subject: Re: st: Accuracy table after mlogit
 
You can do this by hand. I first show how you can recreate the -estat
classification- results for -logit- (not all the concomitant
statistics, but you can do those easily as well), and then follow the
same procedure for -mlogit-. Note that the way the predicted choices
are computed (the choice corresponding to the maximum predicted
probability) is in no way the only way to compute predicted
multinomial choices:

/**************************/
// logit
webuse lbw, clear
logit low age lwt i.race smoke ptl ht ui
estat classification
predict prob
g pred_choice = (prob >= 0.5)
tab pred_choice low  // recreate -estat classification-

// mlogit
webuse sysdsn1, clear
mlogit insure age male nonwhite i.site
predict prob*
egen pred_max = rowmax(prob*)

g pred_choice = .
forv i=1/3 {
 replace pred_choice = `i' if (pred_max == prob`i')
}
local insure_lab: value label insure
label values pred_choice `insure_lab'
tab pred_choice insure
/**************************/


This is what is typically called the confusion matrix.

T


On Tue, Jul 26, 2011 at 7:02 AM,  <N.M.Postel-Vinay@lse.ac.uk> wrote:
> Hi all,
>
> I can't get an accuracy classification table after running a simple multinomial regression (mlogit).
> After a normal logit regression I simply type
>
> estat classification
>
> and it works. But after mlogit I type in the same thing and I get:
>
>
> . estat classification
> invalid subcommand classification
> r(321);
>
> Is there a special command I should use for mlogit in order to get this kind of accuracy table?
>
> Many thanks,
>
> Natacha
>
>
>
> Please access the attached hyperlink for an important electronic communications disclaimer: http://lse.ac.uk/emailDisclaimer
>
> *
> *   For searches and help try:
> *   http://www.stata.com/help.cgi?search
> *   http://www.stata.com/support/statalist/faq
> *   http://www.ats.ucla.edu/stat/stata/
>

*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/


Please access the attached hyperlink for an important electronic communications disclaimer: http://lse.ac.uk/emailDisclaimer

<<winmail.dat>>



© Copyright 1996–2014 StataCorp LP   |   Terms of use   |   Privacy   |   Contact us   |   Site index