Bookmark and Share

Notice: On March 31, it was announced that Statalist is moving from an email list to a forum. The old list will shut down on April 23, and its replacement, statalist.org is already up and running.


[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]

Re: st: Conditional Probabilities after bivariate probit


From   Austin Nichols <austinnichols@gmail.com>
To   statalist@hsphsun2.harvard.edu
Subject   Re: st: Conditional Probabilities after bivariate probit
Date   Fri, 10 Jun 2011 13:30:05 -0400

orc un <deccalorcun@yahoo.com>:
Don't use -mfx-
[http://www.stata.com/statalist/archive/2010-02/msg00045.html];
just read http://www.stata.com/help.cgi?biprobit+postestimation
to make any probability you like:

webuse school, clear
biprobit (private = logptax loginc years) (vote = logptax years)
predict double p11   , p11
predict double p10   , p10
predict double p01   , p01
predict double p00   , p00
predict double pmarg1, pmarg1
predict double pmarg2, pmarg2
predict double pcond1, pcond1
predict double pcond2, pcond2
g double p_1=(p11+p01)/pmarg2
g double p1_=(p11+p10)/pmarg1
su p_1 p1_
g double cp1=p11/(p11+p01)
g double cp2=p11/(p11+p10)
su cp1 pcond1
su cp2 pcond2
g double zp1=p10/(p10+p00)
la var zp1 "Pr(y1==1|y2==0)"
g double zp2=p01/(p01+p00)
la var zp1 "Pr(y2==1|y1==0)"


On Fri, Jun 10, 2011 at 12:48 PM, orc un <deccalorcun@yahoo.com> wrote:
> Dear Statalist users,
>
> I have a question regarding the conditional probability computation for Bivariate Probit model. As far as I know it is possible to compute P(Y1=1|Y2=1) for a bivariate Probit model using the standard Stata commands as mfx, predict(pcond1) .However I would like to compute the P(Y1=1|Y2=0). Is it possible to compute this marginal effects by just creating an alternative dependent variable(Y2c) which takes the complement values of Y2 (ie for Y2=1 then Y2c=0 and for Y2=0 then Y2c=1) and compute P(Y1=1|Y2c=1) instead of P(Y1=1|Y2=0). If yes is it possible to use the same approach for recursive bivariate probit  model??

*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/


© Copyright 1996–2014 StataCorp LP   |   Terms of use   |   Privacy   |   Contact us   |   Site index