Bookmark and Share

Notice: On April 23, 2014, Statalist moved from an email list to a forum, based at statalist.org.


[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]

re: Re: st: coefficient test in different regression models


From   Christopher F Baum <[email protected]>
To   <[email protected]>
Subject   re: Re: st: coefficient test in different regression models
Date   Mon, 4 Oct 2010 13:55:01 -0400

<>
Maarten suggests estimating the two models by pooling. Not a bad idea, but it does impose one additional constraint: that the sigma^2 are the same across equations. For that reason one should at minimum use robust VCE in that case.

An alternative is to use -suest-. Notice that you estimate the individual equations with classical VCE and apply robust on -suest- if desired.

Note that the two approaches yield very similar p-values in this case. It might be interesting to do some simulations of the two approaches to see where they will agree or differ, but with the addition of -robust- Maarten's approach seems to be in line with what -suest- reports.

sysuse auto, clear
constraint 1  _b[1.foreign#c.mpg] = 0
cnsreg price c.mpg#i.foreign   ///
             c.rep78#i.foreign ///
             i.foreign, constr(1) robust

test _b[0b.foreign#c.rep78] = _b[1.foreign#c.rep78]

qui reg price mpg rep78 if !foreign
est sto dom
qui reg price rep78 if foreign
est sto for
suest dom for, robust
test [dom_mean]rep78 = [for_mean]rep78

Kit

Kit Baum   |   Boston College Economics and DIW Berlin   |   http://ideas.repec.org/e/pba1.html
An Introduction to Stata Programming   |   http://www.stata-press.com/books/isp.html
An Introduction to Modern Econometrics Using Stata   |   http://www.stata-press.com/books/imeus.html


*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/


© Copyright 1996–2018 StataCorp LLC   |   Terms of use   |   Privacy   |   Contact us   |   Site index