Bookmark and Share

Notice: On March 31, it was announced that Statalist is moving from an email list to a forum. The old list will shut down on April 23, and its replacement, statalist.org is already up and running.


[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]

Re: st: Suest v/s biprob in stata 11


From   Maarten buis <maartenbuis@yahoo.co.uk>
To   statalist@hsphsun2.harvard.edu
Subject   Re: st: Suest v/s biprob in stata 11
Date   Mon, 5 Jul 2010 13:56:38 +0000 (GMT)

--- On Mon, 5/7/10, Prakash Kashwan wrote:
> From your explanation it seems as if biprob accounts for
> the correlation between the residuals from constituent
> models while suest does not. Am I interpreting it well?

Yes

> If this is indeed the case, it is problematic because the
> way stata runs it, suest is a postestimation command,
> which is supposed to look for correlation between the
> residuals. Am I to assume that suest is not doing what it
> is supposed to do, and I should use biprob instead of
> using suest?  What purpose does suest (as post-estimation
> command) serve then?

The way I understand this is that the inference takes this 
correlation into account in a way that is similar to the
way -robust- standard errors take heteroskedasticity into
acount without estimating the changing error variance.
All that is necesary is that your model for the mean(s) is/are
correct. You can see that in the simulation below. You
want the p-values of both test to be uniformly distributed
as they test an hypothesis that is true in the population,
as is discussed in this post: 
<http://www.stata.com/statalist/archive/2010-06/msg01191.html>

*----------------- begin example -----------------
matrix C = (1, .25 \ .25, 1)

program drop _all
program sim, rclass
	drop _all

	drawnorm e1 e2, n(1000) corr(C)
	gen x = rnormal()

	gen y1=  ( x + e1) > 0
	gen y2 = (-x + e2) > 0

	probit y1 x
	est store a
	probit y2 x
	est store b

	suest a b
	test [a_y1]x = - [b_y2]x
	return scalar p_suest = r(p)
	
	biprobit y1 y2 = x
	test [y1]x = -[y2]x
	return scalar p_biprobit = r(p)
end

set seed 12345
simulate p_biprobit = r(p_biprobit) ///
         p_suest    = r(p_suest),   ///
         reps(10000) : sim

hangroot p_suest,                   ///
         dist(uniform) par(0 1)     ///
         susp notheor ci
		 
hangroot p_biprobit,                ///
         dist(uniform) par(0 1)     ///
         susp notheor ci
*------------------ end example ----------------
(For more on examples I sent to the Statalist see: 
http://www.maartenbuis.nl/example_faq )

This example requires -hangroot-, which you can download
by typing in Stata -ssc install hangroot-.

Hope this helps,
Maarten

--------------------------
Maarten L. Buis
Institut fuer Soziologie
Universitaet Tuebingen
Wilhelmstrasse 36
72074 Tuebingen
Germany

http://www.maartenbuis.nl
--------------------------


      

*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/


© Copyright 1996–2014 StataCorp LP   |   Terms of use   |   Privacy   |   Contact us   |   Site index