st: AW: Generating a dropout dummy variable?

["Martin Weiss" <martin.weiss1@gmx.de>]

<> 

The first part could be:


*************

//Create data
clear*
set obs 1000
set seed 43550

//id
gen int id=_n

//expand to # of time periods
expand 7

bys id: gen int year=_n+1999
gen byte graduated=  /* 
*/ cond(runiform()<0.3 & year==2001,1,0) 

drop if runiform()<.7

xtset id year

//get "dropout" indicator
bys id: egen myvar=total(inlist(year,2000,2001))
bys id: egen myvar2=total(inrange(year,2002,2006))
bys id: gen dropout=((myvar==2)*(myvar2==0))& /* 
*/ ((graduated!=1)*(year==2001))
drop myvar*

//take a look
bys id: egen anydropout=max(dropout)
l if anydropout, sepby(id)
*************


I do not understand the second part. Why would dropout be 1 in 2000 if you saw the guy in 2000?


HTH
Martin

-----Ursprüngliche Nachricht-----
Von: owner-statalist@hsphsun2.harvard.edu [mailto:owner-statalist@hsphsun2.harvard.edu] Im Auftrag von Ignacio Martinez
Gesendet: Sonntag, 27. Juni 2010 15:54
An: statalist@hsphsun2.harvard.edu
Betreff: st: Generating a dropout dummy variable?

Hi,


My panel has the following variables: Year (from 2000 to 2008), ID,
Graduated (an indicator =1 if the student graduated that year) . 

I want to generate a dropout variable. If I see ID==1111 in year==2000
and 2001 but not after that and graduated !=1 in 2001 I want dropout==1
in 2001 . The only other detail is that if a see someone in 2000 and
then I see him again in 2006 with graduated=1 I don't want dropout =1 in
2000 I want other variable that is break=5 (that student took 5 year of
break)


Thanks for the help


-Ignacio


*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/


*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/