Bookmark and Share

Notice: On March 31, it was announced that Statalist is moving from an email list to a forum. The old list will shut down on April 23, and its replacement, statalist.org is already up and running.


[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]

Re: st: RE: RE: what does it mean the default for -mfx- is discrete when it is evaluated at the mean?


From   Maarten buis <maartenbuis@yahoo.co.uk>
To   statalist@hsphsun2.harvard.edu
Subject   Re: st: RE: RE: what does it mean the default for -mfx- is discrete when it is evaluated at the mean?
Date   Wed, 2 Jun 2010 09:14:29 +0000 (GMT)

--- On Tue, 1/6/10, Martin Weiss wrote:
> Still, what is the problem with saying that the marginal
> effect displayed is for going from zero to one, i.e. the
> only move that a dummy can possibly make? The fact that
> the share of ones in your sample is 37% does not change
> this fact, does it?

I am guessing the confusion comes from the fact that the 
marginal effect depends on fixing the values of _all_
explanatory variables, so now Frank sees three values,
0, .37, and 1. However, in computing the discrete change
this middle value is ignored, you only fix the values of
all _other_ explantory variables. 

This is illustrated in the example below, For the marginal
effect of price we need to fix the value of both price and
foreign, but for the "marginal effect" of foreign we only
need to fix the value of price.

*----------------- begin example ----------------------
sysuse auto, clear
gen byte good = rep78 > 3 if rep78 < .
replace price = price / 1000
logit good foreign price
mfx

tempname mprice mforeign xb xb0 xb1
sum price if e(sample), meanonly
scalar `mprice' = r(mean)

sum foreign if e(sample), meanonly
scalar `mforeign' = r(mean)

scalar `xb' = _b[_cons] + _b[price]*`mprice' + _b[foreign]*`mforeign'
di invlogit(`xb')*invlogit(-`xb')*_b[price]

scalar `xb0' = _b[_cons] + _b[price]*`mprice'
scalar `xb1' = _b[_cons] + _b[price]*`mprice' + _b[foreign]
di invlogit(`xb1') - invlogit(`xb0')
*-------------------- end example ----------------------------
(For more on examples I sent to the Statalist see: 
http://www.maartenbuis.nl/example_faq )

Hope this helps,
Maarten

--------------------------
Maarten L. Buis
Institut fuer Soziologie
Universitaet Tuebingen
Wilhelmstrasse 36
72074 Tuebingen
Germany

http://www.maartenbuis.nl
--------------------------


      

*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/


© Copyright 1996–2014 StataCorp LP   |   Terms of use   |   Privacy   |   Contact us   |   Site index