Bookmark and Share

Notice: On March 31, it was announced that Statalist is moving from an email list to a forum. The old list will shut down on April 23, and its replacement, statalist.org is already up and running.


[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]

Re: re: st: Simple regression and Multiple regression?


From   Kit Baum <baum@bc.edu>
To   statalist@hsphsun2.harvard.edu
Subject   Re: re: st: Simple regression and Multiple regression?
Date   Mon, 15 Mar 2010 09:36:23 -0400

On Mar 15, 2010, at 2:33 AM, Rose wrote:

> What about the constant? Is there an existing relationship between simple regression and multiple regression?
> 
> By the way, I found the standard errors of turn were not the same in "reg epsp epst" and "reg price mpg weight turn". Just a decimal difference which can be ignored? 


As the simple regression is a regression of residuals on residuals, both of which are meanzero, the constant is by definition zero, and its estimated value is very close to that.

The difference in standard errors is purely a small-sample degrees of freedom adjustment. In the run below, you will see that suest -- which generates large-sample z-stats -- generates identical SEs. So does -regress-; in the run below, compare the SE of epst adjusted by the ratio of sqrt(72/70) and the SE of turn from multiple regression. They are identical. If you estimated both equations from a very large sample, they would be almost identical. 74 is not a very large sample in asymptotic terms.

--------------------
sysuse auto,clear
reg price mpg weight
predict double epsp, r
qui reg turn mpg weight
predict double epst, r
reg epsp epst
est store fwl
scalar s2 = _se["epst"]
di %12.8f s2 * sqrt(72/70)
// Frisch-Waugh-Lovell theorem says that the coefficient of turn
// should be the same in multiple regression or in a regression
// of price on turn, with the effects of other regressors partialled-off
// from both
// see Baum-Schaffer-Stillman, Stata Journal 2003, 2007
// re ivreg2 fwl() option
reg price mpg weight turn
est store multr
scalar s1 = _se["turn"]
di %12.8f s1
suest multr fwl
test [multr_mean]turn = [fwl_mean]epst 
----------------------

Kit Baum   |   Boston College Economics & DIW Berlin   |   http://ideas.repec.org/e/pba1.html
                              An Introduction to Stata Programming  |   http://www.stata-press.com/books/isp.html
   An Introduction to Modern Econometrics Using Stata  |   http://www.stata-press.com/books/imeus.html


*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/


© Copyright 1996–2014 StataCorp LP   |   Terms of use   |   Privacy   |   Contact us   |   Site index