Statalist


[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]

Re: st: test predicted hazard


From   Austin Nichols <austinnichols@gmail.com>
To   statalist@hsphsun2.harvard.edu
Subject   Re: st: test predicted hazard
Date   Wed, 20 May 2009 13:35:03 -0400

dario <d.sciulli@unich.it> :

I doubt you actually want to test whether predicted hazard rates
differ across groups, since they may differ because predictors vary or
because coefs on X vary or because baseline hazards vary (you don't
mention how you have parametrized time).  If you want to test whether
hazard rates differ across groups, conditional on some X variables,
you may want the first -test- below, which constrains the coefs on all
other variables (including parametrized time), and also the error
variance, to be the same across groups.  If you want to test whether
the baseline hazard at the first time period observed differs,
conditional on X (where now X may have different effects in the two
groups), you might want the second -test- below.  The third -test-
tests whether the hazard evolves differently over time in the two
groups.  You might want something along these lines, depending on how
you have specified your model and other details... you need to clarify
what you want to test, in other words (preferably using a public
dataset to construct any examples). See also
http://www.iser.essex.ac.uk/iser/teaching/module-ec968 and
http://home.fsw.vu.nl/m.buis/wp/survival.html

webuse psidextract, clear
g lnt=ln(t)
bys id (t): g y=sum(union)
bys id (t): replace y=sum(y)
replace y=. if y>1
replace y=. if y==1 & t==1
li id t union y in 1/14, sepby(id) noo
qui cloglog y south ed fem ind occ lnt
test fem
est sto both
qui cloglog y south ed ind occ lnt if fem==1
est sto f
qui cloglog y south ed ind occ lnt if fem==0
est sto m
qui suest m f
test [m_y]_cons=[f_y]_cons
test [m_y]lnt=[f_y]lnt

On Wed, May 20, 2009 at 11:53 AM,  <d.sciulli@unich.it> wrote:
> Dear Statalisters,
>
> I am applying cloglog models to estimate reemployment probabilities
> for four different groups of individuals. I would like to test if the
> predicted hazard rates significantly differ among groups. Does a
> specific test exist?
>
> As alternative, can I simply calculate the predicted hazard (h) and to
> test the null hypothesis (h0=h1) by ttest command? Perhaps should I
> use bootstrapped standard errors?
*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/



© Copyright 1996–2014 StataCorp LP   |   Terms of use   |   Privacy   |   Contact us   |   What's new   |   Site index