--- On Fri, 15/5/09, Tom Trikalinos wrote:
> To compare non-parametric and parametric survival
> analysis models, can I use the AIC and BIC?
> Specifically, I fit Cox PH models and exponential and
> weibull parametric regressions. It was pointed out to
> me that AIC & BIC-based comparisons may not be valid
> (because Cox uses partial likelihood).
>
> PS. I am performing survival analyses to inform a decision
> analysis. For this reason I strongly prefer to fit
> parametric models - will make life easier and restore the
> smile on me face.
You could try estimating a piecewise constant model. The
idea is very similar to the idea behind -stcox-: estimate
a flexible baseline hazard and the explanatory variable
multiplicatively move this baseline hazard up or down.
Alternatively you could model the baseline hazard with
some other flexible curve, like a restricted cubic
spline. See the example below:
*---------------- begin example --------------------------
sysuse cancer, clear
gen long id = _n
stset studytime, failure(died) id(id)
stsplit t, every(1)
gen t3 = floor((t)/3)
// piecewise constant
xi: streg i.t3 i.drug age, dist(exp)
adjust _Idrug_2=1 _Idrug_3=0 age , by(t3) exp gen(haz_piece)
// restricted cubic spline
mkspline tsp=t, cubic knots(5 10 20 30 35)
xi: streg tsp* i.drug age, dist(exp)
adjust _Idrug_2=1 _Idrug_3=0 age , by(t) exp gen(haz_cubic)
twoway line haz* studytim, sort c(J) ///
legend(order(1 "piecewise" "constant" ///
2 "restricted" "cubic spline")) ///
ytitle(hazard)
*----------------- end example ------------------------
Hope this helps,
Maarten
-----------------------------------------
Maarten L. Buis
Institut fuer Soziologie
Universitaet Tuebingen
Wilhelmstrasse 36
72074 Tuebingen
Germany
http://home.fsw.vu.nl/m.buis/
-----------------------------------------
*
* For searches and help try:
* http://www.stata.com/help.cgi?search
* http://www.stata.com/support/statalist/faq
* http://www.ats.ucla.edu/stat/stata/
