Statalist


[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]

Re: st: RE: AW: Test of the difference in growth rate of two variables


From   Austin Nichols <austinnichols@gmail.com>
To   statalist@hsphsun2.harvard.edu
Subject   Re: st: RE: AW: Test of the difference in growth rate of two variables
Date   Fri, 24 Apr 2009 14:25:07 -0400

Herve STOLOWY:
Serial correlation can be handled via clustering, if you have enough
independent clusters, and -suest- can test across two models.
Try e.g.

webuse grunfeld, clear
keep if time>15
* first, linear growth
qui reg invest time
est sto i
qui reg mvalue time
est sto v
suest i v
test [i_mean]time=[v_mean]time
suest i v, cluster(company)
test [i_mean]time=[v_mean]time
* now for exponential growth
g lni=ln(invest)
g lnv=ln(mvalue)
qui reg lni time
est sto lni
qui reg lnv time
est sto lnv
suest lni lnv
test [lni_mean]time=[lnv_mean]time
suest lni lnv, cluster(company)
test [lni_mean]time=[lnv_mean]time


On Fri, Apr 24, 2009 at 12:38 PM, Nick Cox <n.j.cox@durham.ac.uk> wrote:
> More important than any assumption about marginal distributions is what is tacitly assumed here about independence of error terms. If the model of growth fitted isn't right for the data, then the errors will probably be correlated, and that may happen any way. There's no guarantee here that the P-values emitted by -ttest- will be credible without extra checks that the underlying assumptions are valid.
>
> The more general point, I would contend, is that Herve needs an explicit model of growth for inferences to make any sense. There is no plug-in procedure otherwise. There is a dependence structure lurking behind his data -- what he is doing makes no sense if that's not true -- and it's got to be modelled properly. There's no free lunch.
>
> Nick
> n.j.cox@durham.ac.uk

*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/



© Copyright 1996–2014 StataCorp LP   |   Terms of use   |   Privacy   |   Contact us   |   What's new   |   Site index