Claude Francoeur <[email protected]>:
This question makes very little sense, e.g. "Is there only one
inflexion point here (between X1 squared and X1 cubed)?" cannot really
be what you mean to ask. And significance of the type you allude to
involves the whole VCE not just one SE.
I am guessing that you want a picture of how the expected outcome
varies (both point estimates and some kind of confidence region) with
X when you have included X, X^2, and X^3 as regressors, possibly with
other regressors (so you have to pick values for those other
regressors at which to predict outcomes, e.g. the sample means)...
maybe this example will help you sort out what you want:
sysuse nlsw88, clear
g g2=grade^2
g g3=grade^3
qui reg union married age grade g2 g3, r
preserve
keep if e(sample)
collapse married age g2 g3, by(grade) fast
predict _hat
predict _se, stdp
g _ub=_hat+1.96*_se
g _lb=_hat-1.96*_se
tw rarea _ub _lb grade, sort || sc _hat grade
restore
Note that picking the sample mean for regressors that are indicators
(such as married in the example above) does not make a lot of sense,
but produces essentially the same result in a linear model as
averaging over several estimates (this would not be true in general
for a nonlinear model such as -logit- or -probit-).
Alternatively, perhaps you want to estimate the marginal effect of X
on the expected outcome at each value of X, like so:
levelsof grade, loc(g)
foreach i of local g {
lincom _b[grade] + 2*_b[g2]*`i' + 3*_b[g3]*`=(`i')^2'
}
On Tue, Dec 30, 2008 at 12:12 PM, Claude Francoeur
<[email protected]> wrote:
> Hello,
>
> First, I would like to thank Maarten Buis and Ángel Rodríguez Laso for their
> advice (see Polynomial OLS - Dec 25th).
>
> Doing a polynomial OLS and after centering the original variable, we get the
> following results :
>
> Coefficient of X1 (the centered variable) is negative and significant;
> coeff. of X1 squared is negative and not sig. and coeff. of X1 cubed is
> positive and significant.
>
> What would be the graphic representation of such a relation? Is there only
> one inflexion point here (between X1 squared and X1 cubed)?
>
> How should we interpret these results? A tentative explanation would be that
> at a low level of X1, the relation with the dependent variable is negative
> and this relation becomes non significant at a moderate level of X1. Then,
> at higher levels of X1, the relation becomes significantly positive. Is this
> correct?
>
> Thank you very much for your help.
>
> Claude
*
* For searches and help try:
* http://www.stata.com/help.cgi?search
* http://www.stata.com/support/statalist/faq
* http://www.ats.ucla.edu/stat/stata/
