[Date Prev][Date Next][Thread Prev][Thread Next][Date index][Thread index]

Re: st: RE: Different approcah to estimate treatment effect

From   "Austin Nichols" <>
Subject   Re: st: RE: Different approcah to estimate treatment effect
Date   Wed, 28 May 2008 09:32:11 -0400

Gordon et al.--
The second approach you outline arises from a misunderstanding, and is
called the "forbidden regression" by Wooldridge (2002;  With respect to the first
approach, note that the other exogenous vars are not included by
default in the first stage by -treatreg- (unlike in -ivregress- etc.)
and the example below showing calculations "by hand" clarifies how
this can matter.

With a binary endogenous variable, you can use -ivreg2- (or even
-ivreg- I guess), or a control function approach, as well--i.e. that
fact that the endogenous variable is binary does not affect
consistency of the IV estimator.  The -treatreg- estimator offers
improved efficiency, when its assumptions are justified, and can show
big differences in small samples.  Another alternative appears in
18.4.1 of Wooldridge (2002) as Procedure 18.1, shown in the examples
below as iv18.

Note that the example given in -help treatreg- and the manual entry on
-treatreg- probably violates the assumptions (on p.512 of the manual).
The dep var is "wife's wage" but is zero for women with zero hours,
rather than missing, making it more like "Wife's earnings" (made
explicit in my revision of the -treatreg- example below) and so the
errors in the "second stage" regression of wage on observables are not
normally distributed (nor bivariate normal with the unobserved
first-stage error in the latent var regression).  A better model would
use log earnings as the dep var, but then there is selection not only
on who attends college, but who is in the labor force.  Another method
is to assume that expected earnings are a function exp(Xb) of X (see
-help ivpois- for discussion if installed), where some vars in X may
be endogenous (using -ivpois- one could also include the zero-earnings
obs in the estimation of that model).

---cut and paste from here to Command window in Stata---
* first update user-written ados required for examples
ssc inst estout, replace
ssc inst ivreg2, replace
ssc inst ivpois, replace

webuse labor, clear
g byte wc=(we>12) if we<.
la var wc "wife went to college"
g earn=(whrs*ww)
replace ww=ln(earn)
la var ww "log earnings"
keep if ww<.
treatreg ww wa cit, treat(wc=wmed wfed) twostep
est sto ts1
probit wc wmed wfed
set type double
predict xb, xb
g res=cond(wc==1,normalden(xb)/normal(xb),-normalden(xb)/(1-normal(xb)))
drop xb
reg ww wa cit wc res
est sto byhand1
treatreg ww wa cit, treat(wc=wmed wfed wa cit) twostep
est sto ts2
probit wc wmed wfed wa cit
predict xb, xb
g r2=cond(wc==1,normalden(xb)/normal(xb),-normalden(xb)/(1-normal(xb)))
reg ww wa cit wc r2
est sto byhand2
esttab ts1 byhand1 ts2 byhand2, nogaps mti

ivreg2 ww wa cit (wc=wmed wfed)
est sto iv1
reg wc wmed wfed wa cit
predict wchat
ivreg2 ww wa cit (wc=wchat)
est sto iv18
ivpois earn wa cit, endog(wc) exog(wmed wfed)
est sto ivpois
esttab ts1 ts2 iv1 iv18 ivpois, nogaps mti scalar(idstat widstat)

Note above how the -ivreg2- results are the same, except that using
the predicted value as the excluded instrument artificially pumps up
the weak-ID stat.  See also "Causal inference with observational data"
in Stata Journal 7(4): 507-541

On Wed, May 28, 2008 at 7:07 AM, Shehzad Ali <> wrote:
> In the past I have used the first approach, i.e. using both imr as well as
> the endogenous variable in the final OLS. IMR corrects for the unobserved
> heterogeneity.
> -----Original Message-----
> From: Gordon <>
> Sent: 27 May 2008 16:30
> Greetings!
> Suppose I want to estimate a treatment effect model,
> Y = b*X+a*D + e
> D is the treatment and endogenous, where D = 1 if g*Z>0, and 0 otherwise.
> If I understand correctly, treatreg in Stata does the following:
> 1. in the first stage  using a probit model (regress D on probit(g*Z))
> to estimate g.
> 2. In the second stage, add the inverse mills ratio to the equation Y
> = Xb+a*D + e and estimate using OLS.
> However, I have seen another approach to estimate the treatment effect:
> 1.  in the first stage  using a probit model (regress D on
> probit(g*Z)) to estimate g.
> 2. replacing D with the estimated probabilities from the first stage
> and then run the OLS.
> I am not clear how this second approach is derived. I read through Lee
> and Trost (1978 journal of econometrics) but there is not much
> details.
> Most important, which approach is the preferred one?
> Thanks for your attention.
> Gordon
*   For searches and help try:

© Copyright 1996–2014 StataCorp LP   |   Terms of use   |   Privacy   |   Contact us   |   What's new   |   Site index