# st: RE: simulation

 From "Maarten Buis" To Subject st: RE: simulation Date Mon, 29 May 2006 12:13:22 +0200

```---Azam Alavi wrote:
> I estimated an ordered probit model for the level of
> education(effective years of schooling) as a dependent variable and
> matrix of M including age,sex,location,average of education in the
> household as independet variables.
>
> Now, I'm trying to simulate the educational expansion in a way that
> the vector of cut_off points c(ei)  in the ordered probit model
> translate leftwards by a constant vector e`>0 such that
> c'(ei)=c(ei)-e` and the characteristics of M will be the same.The
> program must iterate on successively higher values of e` until the
> mean of simulated distribution of years of schooling converged to ten.

Azam:
You want to keep the linear predictor (explanatory variables and
their effects) constant and change the cut-off values, and see
what happens to the mean level of education. -oprobit- models
probabilities of belonging to certain ordered categories, e.g.
educational levels. If you are willing to assign numbers to
these categories, e.g. effective years of schooling, than you
these probabilities can be translated to an average level of
education. If we have three levels of education and assign them
values 1,2,3, and each individual as probabilities p1, p2, and p3
of belonging to each of these three levels, than the expected
level of education for each individual is p1*1 + p2*2 + p3*3. The
mean of these individual expected levels of education is than what
you are interested in. Lets call the linear predictor xb, you can
get that with the command -predict xb, xb- after the -oprobit-
command. Than the probability of achieving only level 1 is
norm(_b[/cut1] - xb), using the formulas in the last technical note
of the -oprobit- entry in the manual. So if we move the cutoff point
.1 to the left, the predicted probability would be
norm( (_b[/cut1]-.1) - xb). In order to do what you want we have to
do this for all probabilities, translate the probabilities to
expected levels of education, compute the mean of these, and repeat
doing this for multiple shifts to the left. I have done that in the
example below.

On a more substantive note, did you know that the behavioral model
underlying ordered probit is rather peculiar when applying it to
educational levels? It assumes that parents make one choice: the
highest level of education their child will get. In some educational
systems this means that when the child is 12 the, parents make one
unchangeable decision. After that they won't change that choice,
because they are unable to learn anything new about the abilities and
whishes of the child. There are smart people who like this model
because they equate it with a rational choice model, e.g. Cameron and
Heckman (1998) propose for this reason a variation on the ordered
probit as an appropriate model for education. This model was proposed
in reaction to the than dominant sequential logit/Mare model
(Mare 1980, 1981). Cameron and Heckman showed that that model assumed
that people take one transition (e.g. step from primary to secondary
education) at the time and do not take into account that ones you
choose not to go to secondary education you can't go to tertiary. A
characteristic of the Mare model they call myopia. I think the myopia
assumption of the Mare model is less severe than the inability to
learn assumption of the ordered probit. If you agree with that, and
you used -oprobit- because it is a simpler model of the highest
achieved level of education, than I have shown
(http://home.fsw.vu.nl/m.buis/wp/locfit.html) that you could better
use simple linear regression than ordered logit (or ordered probit)
because OLS has a really nice relation with the sequential logit/Mare
model.

HTH,
Maarten

*------------begin example-----------
sysuse nlsw88, clear
gen ed = 1 if grade <12
replace ed = 3 if grade >=16
tab ed
gen nonwhite = race >1
oprobit ed smsa south nonwhite age

predict p1 p2 p3
gen ey = p1*1 + p2*2 + p3*3
sum ey
matrix meaned = 0,r(mean)

predict xb, xb
forvalues i = .1(.1)3 {
drop p1 p2 p3 ey
gen p1 = norm((_b[/cut1]-`i')-xb)
gen p2 = norm((_b[/cut2]-`i')-xb)-norm((_b[/cut1]-`i')-xb)
gen p3 = norm(xb-(_b[/cut2]-`i'))
gen ey = p1*1 + p2*2 + p3*3
sum ey, meanonly
di "shift " round(`i', .1) " to the left results in mean education of " r(mean)
matrix meaned = meaned \ `i' , r(mean)
}
matrix list meaned
svmat meaned
twoway line meaned2 meaned1, xtitle("shift to the left") ytitle("mean education")
*------------------end example------------------

Cameron, Stephen V. and James J. Heckman. 1998. Life Cycle Schooling and Dynamic
Selection Bias: Models and Evidence for Five Cohorts of American Males." The Journal of
Political Economy 106(2):262-333.

Mare, Robert D. 1980. Social Background and School Continuation Decisions." Journal of
the American Statistical Association 75(370):295-305.

Mare, Robert D. 1981. Change and Stability in Educational Stratiffcation." American Sociological Review 46(1):72-87.

-----------------------------------------
Maarten L. Buis
Department of Social Research Methodology
Vrije Universiteit Amsterdam
Boelelaan 1081
1081 HV Amsterdam
The Netherlands

Buitenveldertselaan 3 (Metropolitan), room Z214

+31 20 5986715

http://home.fsw.vu.nl/m.buis/
-----------------------------------------

*
*   For searches and help try:
*   http://www.stata.com/support/faqs/res/findit.html
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/
```