Stata The Stata listserver
[Date Prev][Date Next][Thread Prev][Thread Next][Date index][Thread index]

st: RE: St: Chamberlain's PPA


From   "Nick Cox" <n.j.cox@durham.ac.uk>
To   <statalist@hsphsun2.harvard.edu>
Subject   st: RE: St: Chamberlain's PPA
Date   Thu, 6 Feb 2003 18:57:39 -0000

chris@cmcintyre.info
> 
> I have been asked to implement Chamberlain's Percent 
> Positive Agreement (PPA) which is the number of 
> occurrences for which both observors report a positive 
> result out of the total number of observations for which 
> at least one observor reports a positive result (see Szklo 
> and Nieto 2000).  
> 
> My questions to the list are: 
> 
> 1) Is there an existing Stata procedure to implement 
> Chamberlain's PPA?
> 
> 2) Do any list members have alternatives approaches to 
> Chamberlain's PPA? 
> 

I have never heard of this, but no matter. Nor 
does the reference help, absent a book or journal title. 

It may well be lurking somewhere in Stataland under 
another name. If not, 

Suppose obs1 and obs2 are variables containing 
results of the two observers. 

Then 

qui count if (obs1 > 0 & obs1 < .) | (obs2 > 0 & obs2 < .) 
local denom = r(N) 
qui count if (obs1 > 0 & obs1 < .) & (obs2 > 0 & obs2 < .) 
di `r(N)' / `denom' 

Here is some code: 

=========== begin ppa.ado
program def ppa, rclass 
        version 7 
        syntax varlist(numeric min=2 max=2) [if] [in] 
        marksample touse 
        tokenize `varlist' 
        args o1 o2 
        qui count if ((`o1' > 0) | (`o2' > 0)) & `touse' 
        local denom = r(N) 
        qui count if (`o1' > 0) & (`o2' > 0) & `touse' 
        local ppa = r(N) / `denom' 
        di 
        di as text "Chamberlain's PPA measure  " _c 
        di as res %5.4f `ppa' "  (" %5.2f 100 * `ppa' " %)"
end 
============== end ppa.ado 

Syntax: ppa obs1 obs2 [if] [in] 

On measures of agreement in general, it is 
difficult to comment without knowing 
research objectives, etc. 

The program -pairplot- recently posted on SSC 
is directly aimed at graphic comparison of 
such paired variables. 


Nick 
n.j.cox@durham.ac.uk 

*
*   For searches and help try:
*   http://www.stata.com/support/faqs/res/findit.html
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/



© Copyright 1996–2014 StataCorp LP   |   Terms of use   |   Privacy   |   Contact us   |   What's new   |   Site index