Stata 15 help for putdocx

[P] putdocx -- Generate Office Open XML (.docx) file

Syntax

Create document for export

putdocx begin [, pagesize(psize) landscape font(fspec)]

Add paragraph to document

putdocx paragraph [, paragraph_options]

Add text to paragraph

putdocx text (exp) [, text_options]

Add image to paragraph

putdocx image filename [, image_options]

Add table to document

putdocx table tablename = (nrows, ncols) [, table_options]

putdocx table tablename = data(varlist) [if] [in] [, varnames obsno table_options]

putdocx table tablename = matrix(matname) [, nformat(%fmt) rownames colnames table_options]

putdocx table tablename = mata(matname) [, nformat(%fmt) table_options]

putdocx table tablename = etable[(#1 #2 ... #n)] [, table_options]

putdocx table tablename = returnset [, table_options]

Add content to cell

putdocx table tablename(i,j) = (exp) [, cell_options]

putdocx table tablename(i,j) = image(filename) [, image_options cell_options]

putdocx table tablename(i,j) = table(mem_tablename) [, cell_options]

Alter table layout

putdocx table tablename(i,.), row_col_options

putdocx table tablename(.,j), row_col_options

Customize format of cells or table

putdocx table tablename(i,j), cell_options

putdocx table tablename(numlist_i,.), cell_fmt_options

putdocx table tablename(.,numlist_j), cell_fmt_options

putdocx table tablename(numlist_i,numlist_j), cell_fmt_options

putdocx table tablename(.,.), cell_fmt_options

Add page break to document

putdocx pagebreak

Add section break to document

putdocx sectionbreak [, pagesize(psize) landscape]

Describe current document

putdocx describe

Describe table

putdocx describe tablename

Close and save document

putdocx save filename [, replace|append]

Close without saving

putdocx clear

Append content of documents

putdocx append filename1 filename2 [filename3 [...]] [, saving( filename[, replace])]

tablename specifies the name of a new table. The name must be a valid name according to Stata's naming conventions; see [U] 11.3 Naming conventions.

paragraph_options Description ------------------------------------------------------------------------- style(pstyle) set paragraph text with specific style font(fspec) set font, font size, and font color halign(hvalue) set paragraph alignment valign(vvalue) set vertical alignment of characters on each line indent(indenttype, #[unit]) set paragraph indentation spacing(position, #[unit]) set spacing between lines of text shading(sspec) set background color, foreground color, and fill pattern -------------------------------------------------------------------------

text_options Description ------------------------------------------------------------------------- nformat(%fmt) specify numeric format for text font(fspec) set font, font size, and font color bold format text as bold italic format text as italic script(sub|super) set subscript or superscript formatting of text strikeout strikeout text underline[(upattern)] underline text using specific pattern shading(sspec) set background color, foreground color, and fill pattern linebreak[(#)] add line breaks after text allcaps format text as all caps smallcaps format text as small caps -------------------------------------------------------------------------

image_options Description ------------------------------------------------------------------------- width(#[unit]) set image width height(#[unit]) set image height linebreak[(#)] add line breaks after image link insert link to image file -------------------------------------------------------------------------

table_options Description ------------------------------------------------------------------------- memtable keep table in memory rather than add it to document width(#[unit|%]) set table width halign(hvalue) set table horizontal alignment indent(#[unit]) set table indentation layout(layouttype) adjust column width cellmargin(cmarg, #[unit]) set margins for each table cell cellspacing(#[unit]) set spacing between adjacent cells and the edges of the table border(bspec) set pattern, color, and width for border headerrow(#) set number of the top rows that constitute the table header title(string) add a title to the table note(string) add notes to the table -------------------------------------------------------------------------

cell_options Description ------------------------------------------------------------------------- append append objects to current content of cell rowspan(#) merge cells vertically colspan(#) merge cells horizontally span(#1, #2) merge cells both horizontally and vertically linebreak[(#)] add line breaks into the cell cell_fmt_options options that control the look of cell contents -------------------------------------------------------------------------

row_col_options Description ------------------------------------------------------------------------- nosplit prevent row from breaking across pages addrows(# [, before|after]) add # rows in specified location addcols(# [, before|after]) add # columns in specified location drop drop specified row or column cell_fmt_options options that control the look of cell contents -------------------------------------------------------------------------

cell_fmt_options Description ------------------------------------------------------------------------- halign(hvalue) set horizontal alignment valign(vvalue) set vertical alignment border(bspec) set pattern, color, and width for border shading(sspec) set background color, foreground color, and fill pattern nformat(%fmt) specify numeric format for cell text font(fspec) set font, font size, and font color bold format text as bold italic format text as italic * script(sub|super) set subscript or superscript formatting of text strikeout strikeout text underline[(upattern)] underline text using specific pattern allcaps format text as all caps smallcaps format text as small caps ------------------------------------------------------------------------- * May only be specified when formatting a single cell.

fspec is

fontname [, size [, color]]

fontname may be any valid font installed on the user's computer. If fontname includes spaces, then it must be enclosed in double quotes.

size is a numeric value that represents font size measured in points. The default is 11.

color sets the text color.

sspec is

bgcolor [, fgcolor [, fpattern]]

bgcolor specifies the background color.

fgcolor specifies the foreground color. The default foreground color is black.

fpattern specifies the fill pattern. The most common fill patterns are solid for a solid color (determined by fgcolor), pct25 for 25% gray scale, pct50 for 50% gray scale, and pct75 for 75% gray scale. A complete list of fill patterns is shown in the Appendix.

bspec is

bordername[, bpattern [, bcolor [, bwidth]]]

bordername specifies the location of the border.

bpattern is a keyword specifying the look of the border. The most common patterns are single, dashed, dotted, and double. The default is single. For a complete list of border patterns, see the Appendix. To remove an existing border, specify nil as the bpattern.

bcolor specifies the border color.

bwidth is defined as #[unit] and specifies the border width. The default border width is 0.5 points. If # is specified without the optional unit, inches is assumed. bwidth may be ignored if you specify a width larger than that allowed by the program used to view the .docx file. We suggest using 12 points or less or an equivalent specification.

unit may be in (inch), pt (point), cm (centimeter), or twip (twentieth of a point). An inch is equivalent to 72 points, 2.54 centimeters, or 1440 twips. The default is in.

color, bgcolor, fgcolor, and bcolor may be one of the colors listed in the table of colors in the Appendix; a valid RGB value in the form ### ### ###, for example, 171 248 103; or a valid RRGGBB hex value in the form ######, for example, ABF867.

Output types for tables

The following output types are supported when creating a new table using putdocx table tablename:

(nrows, ncols) creates an empty table with nrows rows and ncols columns. Microsoft Word 2007/2010 allows a maximum of 63 columns in a table.

data(varlist) [if] [in] [, varnames obsno] adds the current Stata dataset in memory as a table to the active document. varlist contains a list of the variable names from the current dataset in memory. if and in may be used to restrict the data to be added to the table.

matrix(matname) [, nformat(%fmt) rownames colnames] adds a matrix called matname as a table to the active document. The elements of the matrix are formatted using %fmt. If nformat() is not specified, then %12.0g is used.

mata(matname) [, nformat(%fmt)] adds a Mata matrix called matname as a table to the active document. The elements of the matrix are formatted using %fmt. If nformat() is not specified, then %12.0g is used.

etable[(#1 #2 ... #n)] adds an automatically generated table to the active document. The table may be derived from the coefficient table of the last estimation command, from the table of margins after the last margins command, or from the table of results from one or more models displayed by estimates table.

Note that if the estimation command outputs n > 1 coefficient tables, the default is to add all tables and assign the corresponding table names tablename1, tablename2, ..., tablename_n. To specify which tables to add, supply the optional numlist to etable. For example, to add the first and third tables from the estimation output, specify etable(1 3). A few estimation commands do not support the etable output type. See Unsupported estimation commands in [P] putdocx for a list of estimation commands that have displayed output that is not supported by putdocx.

returnset exports a group of Stata return values to a table in the active document. It is intended primarily for use by programmers and by those who want to do further processing of their exported results in the active document. returnset may be one of the following:

returnset Description --------------------------------------------------------- escalars All ereturned scalars rscalars All returned scalars emacros All ereturned macros rmacros All returned macros ematrices All ereturned matrices rmatrices All returned matrices e* All ereturned scalars, macros, and matrices r* All returned scalars, macros, and matrices ---------------------------------------------------------

The following output types are supported when adding content to an existing table using putdocx table tablename(i, j):

(exp) writes a valid Stata expression to a cell. See [U] 13 Functions and expressions.

image(filename) adds a portable network graphics (.png), JPEG (.jpg), Windows metafile (.wmf), device-independent bitmap (.dib), enhanced metafile (.emf), or bitmap (.bmp) file to the table cell. If filename contains spaces, it must be enclosed in double quotes.

table(mem_tablename) adds a previously created table, identified by mem_tablename, to the table cell.

The following combinations of tablename(numlist_i,numlist_j) (see [U] 11.1.8 numlist for valid specifications) can be used to format a cell or range of cells in an existing table:

tablename(i,j) specifies the cell on the ith row and jth column.

tablename(i,.) and tablename(numlist_i,.) specify all cells on the ith row or on the rows identified by numlist_i.

tablename(.,j) and tablename(.,numlist_j) specify all cells in the jth column or in the columns identified by numlist_j.

tablename(.,.) specifies the whole table.

Description

putdocx writes paragraphs, images, and tables to an Office Open XML file (.docx). It may also be used to format each object added. This allows you to automate exporting and formatting of, for example, Stata estimation results and also to generate various reports based on those results. The generated file is compatible with Microsoft Word 2007 and later. Below, we provide a summary of the commands to add and format the content of a .docx file.

putdocx begin creates the .docx file for export.

putdocx paragraph adds a new paragraph to the active document. The newly created paragraph becomes the active paragraph. All subsequent text or images will be appended to the active paragraph.

putdocx text (exp) adds content to the paragraph created by putdocx paragraph. exp may be a valid Stata expression (see [U] 13 Functions and expressions) or a normal string.

putdocx image filename embeds in the document a portable network graphics (.png), JPEG (.jpg), enhanced metafile (.emf), or tagged image file format (.tif) file in the active paragraph. filename is the path to the image file. It may be either the full path or the relative path from the current working directory. Adding an image is not supported on console Stata for Mac.

putdocx table tablename creates a new table that can be identified by its assigned name, tablename, for future modifications. Tables may be created from several output types, including the data in memory, matrices, and estimation results; see Output types for tables for a complete list and a description of each type.

putdocx pagebreak adds a page break to the document, placing subsequent content on the next page of the document.

putdocx sectionbreak adds a new section to the active document that starts on the next page. It lets you vary the page size and the orientation of the pages within a single document and is most useful when you want to mix portrait and landscape layouts.

putdocx describe describes the current .docx file or a table within the current .docx file.

putdocx save closes and saves the .docx file.

putdocx clear closes the .docx file without saving the changes.

putdocx append appends the contents of the one or more .docx files to another .docx file.

Options

Options are presented under the following headings:

Options for putdocx begin Options for putdocx paragraph Options for putdocx text Options for putdocx image Options for putdocx table table_options cell_options row_col_options cell_fmt_options image_options Options for putdocx sectionbreak Options for putdocx save Option for putdocx append

Options for putdocx begin

pagesize(psize) sets the page size of the document. psize may be letter, legal, A3, A4, or B4JIS. The default is pagesize(letter).

landscape changes the document orientation from portrait to landscape.

font(fontname[, size[, color]]) sets the font, font size, and font color for the document. Note that the font size and font color may be specified individually without specifying fontname. Use font("", size) to specify font size only. Use font("", "", color) to specify font color only. For both cases, the default font will be used.

Options for putdocx paragraph

style(pstyle) specifies that the text in the paragraph be formatted with style pstyle. Common values for pstyle are Title, Subtitle, and Heading1. See the complete list of paragraph styles in the Appendix.

font(fontname[, size[, color]]) sets the font, font size, and font color for the text within the paragraph. Note that the font size and font color may be specified individually without specifying fontname. Use font("", size) to specify font size only. Use font("", "", color) to specify font color only. For both cases, the default font will be used.

Specifying font() with putdocx paragraph overrides font settings specified with putdocx begin.

halign(hvalue) sets the horizontal alignment of the text within the paragraph. hvalue may be left, right, center, both, or distribute. distribute and both justify text between the left and right margins equally, but distribute also changes the spacing between words and characters. The default is halign(left).

valign(vvalue) sets the vertical alignment of the characters on each line when the paragraph contains characters of varying size. vvalue may be auto, baseline, bottom, center, or top. The default is valign(baseline).

indent(indenttype, #[unit]) specifies that the paragraph be indented by # units. indenttype may be left, right, hanging, or para. left and right indent # units from the left or the right, respectively. hanging uses hanging indentation and indents lines after the first line by # inches unless another unit is specified. para uses standard paragraph indentation and indents the first line by # inches unless another unit is specified. This option may be specified multiple times in a single command to accommodate different indentation settings. If both indent(hanging) and indent(para) are specified, only indent(hanging) is used.

spacing(position, #[unit]) sets the spacing between lines of text. position may be before, after, or line. before specifies the space before the first line of the current paragraph, after specifies the space after the last line of the current paragraph, and line specifies the space between lines within the current paragraph. This option may be specified multiple times in a single command to accommodate different spacing settings.

shading(bgcolor[, fgcolor[, fpattern]]) sets the background color, foreground color, and fill pattern for the paragraph.

Options for putdocx text

nformat(%fmt) specifies the numeric format of the text when the content of the new text appended to the paragraph is a numeric value. This setting has no effect when the content is a string.

font(fontname[, size[, color]]) sets the font, font size, and font color for the new text within the active paragraph. Note that the font size and font color may be specified individually without specifying fontname. Use font("", size) to specify font size only. Use font("", "", color) to specify font color only. For both cases, the default font will be used.

Specifying font() with putdocx text overrides all other font settings, including those specified with putdocx begin and putdocx paragraph.

bold specifies that the new text in the active paragraph be formatted as bold.

italic specifies that the new text in the active paragraph be formatted as italic.

script(sub|super) changes the script style of the new text. script(sub) makes the text a subscript. script(super) makes the text a superscript.

strikeout specifies that the new text in the active paragraph have a strikeout mark.

underline[(upattern)] specifies that the new text in the active paragraph be underlined and optionally specifies the format of the line. By default, a single underline is used. The optional upattern may be any of the patterns listed in the Appendix. The most common patterns are double, dash, and none.

shading(bgcolor[, fgcolor[, fpattern]]) sets the background color, foreground color, and fill pattern for the active paragraph. Specifying shading() with putdocx text overrides shading specifications from putdocx paragraph.

linebreak[(#)] specifies that one or # line breaks be added after the new text.

allcaps specifies that all letters of the new text in the active paragraph be capitalized.

smallcaps specifies that the new text in the active paragraph be capitalized with larger capitals for uppercase letters.

Options for putdocx image

width(#[unit]) sets the width of the image. If the width is larger than the body width of the document, then the body width is used. If width() is not specified, then the default size is used; the default is determined by the image information and the body width of the document.

height(#[unit]) sets the height of the image. If height() is not specified, then the height of the image is determined by the width and the aspect ratio of the image.

linebreak[(#)] specifies that one or # line breaks be added after the new image.

link specifies that a link to the image filename be inserted into the document. If the image is linked, then the referenced file must be present so that the document can display the image.

Options for putdocx table

table_options

memtable specifies that the table be created and held in memory instead of being added to the active document. By default, the table is added to the document immediately after it is created. This option is useful if the table is intended to be added to a cell of another table or to be used multiple times later.

width(#[unit|%]) sets the table width. # may be an absolute width or a percent of the default table width, which is determined by the page width of the document. For example, width(50%) sets the table width to 50% of the default table width. The default is width(100%).

halign(hvalue) sets the horizontal alignment of the table within the page. hvalue may be left, right, or center. The default is halign(left).

indent(#[unit]) specifies the table indentation from the left margin of the current document.

layout(layouttype) adjusts the column width of the table. layouttype may be fixed, autofitwindow, or autofitcontents. fixed means the width is the same for all columns in the table. When autofitwindow is specified, the column width automatically resizes to fit the window. When autofitcontents is specified, the table width is determined by the overall table layout algorithm, which automatically resizes the column width to fit the contents. The default is layout(autofitwindow).

cellmargin(cmarg, #[unit]) sets the cell margins for table cells. cmarg may be top, bottom, left, or right. This option may be specified multiple times in a single command to accommodate different margin settings.

cellspacing(#[unit]) sets the spacing between adjacent cells and the edges of the table.

border(bordername [, bpattern [, bcolor [, bwidth]]]) adds a single border in the location specified by bordername, which may be start, end, top, bottom, insideH (inside horizontal borders), insideV (inside vertical borders), or all. Optionally, you may change the pattern, color, and width for the border by specifying bpattern, bcolor, and bwidth.

This option may be specified multiple times in a single command to accommodate different border settings. If multiple border() options are specified, they are applied in the order specified from left to right.

headerrow(#) sets the top # rows to be repeated as header rows at the top of each page on which the table is displayed. This setting has a visible effect only when the table crosses multiple pages.

varnames specifies that the variable names be included as the first row in the table when the table is created using the dataset in memory. By default, only the data values are added to the table.

obsno specifies that the observation numbers be included as the first column in the table when the table is created using the dataset in memory. By default, only the data values are added to the table.

nformat(%fmt) specifies the numeric format to be applied to the source values when creating the table from a Stata or Mata matrix. The default is nformat(%12.0g).

rownames specifies that the row names of the Stata matrix be included as the first column in the table. By default, only the matrix values are added to the table.

colnames specifies that the column names of the Stata matrix be included as the first row in the table. By default, only the matrix values are added to the table.

title(string) inserts a row without borders above the current table. The added row spans all the columns of the table and contains string as text. The added row shifts all other table contents down by one row. You should account for this when referencing table cells in subsequent commands.

note(string) inserts a row without borders to the bottom of the table. The added row spans all the columns of the table. This option may be specified multiple times in a single command to add notes on new lines within the same cell. Note text is inserted in the order it was specified from left to right.

cell_options

append specifies that the new content for the cell be appended to the current content of the cell. If append is not specified, then the current content of the cell is replaced by the new content.

rowspan(#) sets the specified cell to span vertically # cells downward. If the span exceeds the total number of rows in the table, the span stops at the last row.

colspan(#) sets the specified cell to span horizontally # cells to the right. If the span exceeds the total number of columns in the table, the span stops at the last column.

span(#1, #2) sets the specified cell to span #1 cells downward and span #2 cells to the right.

linebreak[(#)] specifies that one or # line breaks be added after the text, the image, or the table within the cell.

row_col_options

nosplit specifies that row i not split across pages. When a table row is displayed, a page break may fall within the contents of a cell on the row, causing the contents of that cell to be displayed across two pages. nosplit prevents this behavior. If the entire row cannot fit on the current page, the row will be moved to the start of the next page.

addrows(#[, before|after]) adds # rows to the current table before or after row i. If before is specified, the rows are added before the specified row. By default, rows are added after the specified row.

addcols(#[, before|after]) adds # columns to the current table to the right or the left of column j. If before is specified, the columns are added to the left of the specified column. By default, the columns are added after, or to the right of, the specified column.

drop deletes row i or column j from the table.

cell_fmt_options

halign(hvalue) sets the horizontal alignment of the specified cell or of all cells in the specified row, column, or range. hvalue may be left, right, or center. The default is halign(left).

valign(vvalue) sets the vertical alignment of the specified cell or of all cells in the specified row, column, or range. vvalue may be top, bottom, or center. The default is valign(top).

border(bordername [, bpattern [, bcolor [, bwidth]]]) adds a single border to the specified cell or of all cells in the specified row, column, or range in the given location. bordername may be start, end, top, bottom, or all. Optionally, you may change the pattern, color, and width for the border by specifying bpattern, bcolor, and bwidth.

This option may be specified multiple times in a single command to accommodate different border settings. If multiple border() options are specified, they are applied in the order specified from left to right.

shading(bgcolor[, fgcolor[, fpattern]]) sets the background color, foreground color, and fill pattern for the specified cell or of all cells in the specified row, column, or range.

nformat(%fmt) applies the Stata numeric format %fmt to the text within the specified cell or within all cells in the specified row, column, or range. This setting has no effect when the content of the cell is a numeric value.

font(fontname[, size[, color]]) sets the font, font size, and font color for the current text within the specified cell or within all cells of the specified row, column, or range. Note that the font size and font color may be specified individually without specifying fontname. Use font("", size) to specify font size only. Use font("", "", color) to specify font color only. For both cases, the default font will be used.

bold applies bold formatting to the current text within the specified cell or within all cells in the specified row, column, or range.

italic applies italic formatting to the current text within the specified cell or within all cells in the specified row, column, or range.

script(sub|super) changes the script style of the current text. script(sub) makes the text a subscript. script(super) makes the text a superscript. script() may only be specified when formatting a single cell.

strikeout adds a strikeout mark to the current text within the specified cell or within all cells in the specified row, column, or range.

underline adds an underline to the current text within the specified cell or within all cells in the specified row, column, or range. By default, a single underline is used. underline(upattern) can be used to change the format of the line, where upattern may be any of the patterns listed in the Appendix. The most common patterns are double, dash, and none.

allcaps uses capital letters for all letters of the current text within the specified cell or within all cells in the specified row, column, or range.

smallcaps uses capital letters for all letters of the current text within the specified cell or within all cells in the specified row, column, or range. Unlike allcaps, larger capitals are used for uppercase letters.

image_options

width(#[unit]) sets the width of the image. If the width is larger than the width of the cell, then the width is used. If width() is not specified, then the default size is used; the default is determined by the image information and the width of the cell.

height#[unit]) sets the height of the image. If height() is not specified, then the height of the image is determined by the width and the aspect ratio of the image.

linebreak[(#)] specifies that one or # line breaks be added after the new image.

link specifies that a link to the image filename be inserted into the document. If the image is linked, then the referenced file must be present so that the document can display the image.

Options for putdocx sectionbreak

pagesize(psize) sets the page size of the section. psize may be letter, legal, A3, A4, or B4JIS. The default is pagesize(letter).

landscape changes the section orientation from portrait to landscape.

Options for putdocx save

replace specifies to overwrite filename, if it exists, by the contents of the document in memory.

append specifies to append the contents of the document in memory to the end of filename.

Option for putdocx append

saving(filename[, replace]) specifies to append the contents of the existing document filename2 to the end of filename1 and then write the result to the new document filename. If filename already exists, it can be overwritten by specifying replace. By default, filename1 is replaced with the document created by appending content from filename2.

If more than two files are specified, the contents are appended in the order in which they are listed. For example, filename2 is appended to filename1, filename3 is appended to the result of the first append, and so forth.

Examples

Setup . sysuse auto

Create a .docx document in memory . putdocx begin

Use summarize to obtain summary statistics on mpg . summarize mpg

Add a new paragraph to the active document and append text to it . putdocx paragraph . putdocx text ("In this dataset, there are `r(N)' models") . putdocx text (" of automobiles. The maximum MPG among them is ") . putdocx text (r(max)), bold . putdocx text (".")

putdocx text can be used to break long sentences into pieces, and each piece in the paragraph can be customized to have a different style. Above, r(max) is formatted as bold.

Create a scatterplot and export the graph as a .png file . scatter mpg price . graph export auto.png Add the .png file to the to the document in a new paragraph that is centered horizontally . putdocx paragraph, halign(center) . putdocx image auto.png, width(4)

Fit a linear regression model of mpg as a function of weight and foreign . regress mpg weight foreign

Export the estimation results to the document as a table with the name tbl1 . putdocx table tbl1 = etable, width(100%)

Keep only the point estimates and confidence intervals . putdocx table tbl1(.,5), drop . putdocx table tbl1(.,4), drop . putdocx table tbl1(.,3), drop

Modify the column headings to omit the dependent variable name . putdocx table tbl1(1,2) = ("")

Export the first 15 observations of the make, price, and mpg variables from the dataset in memory . putdocx table tbl1 = data("make price mpg") in 1/15, varnames

Save the document to disk . putdocx save example.docx

Stored results

putdocx describe tablename stores the following in r():

Scalars r(nrows) number of rows in the table r(ncols) number of columns in the table

Appendix

Paragraph styles

pstyle ------------------------- Title Subtitle Heading1 Heading2 Heading3 Heading4 Heading5 Heading6 Heading7 Heading8 Heading9 -------------------------

Colors

color ---------------------------------------------------- aliceblue ghostwhite navajowhite antiquewhite gold navy aqua goldenrod oldlace aquamarine gray olive azure green olivedrab beige greenyellow orange bisque honeydew orangered black hotpink orchid blanchedalmond indianred palegoldenrod blue indigo palegreen blueviolet ivory paleturquoise brown khaki palevioletred burlywood lavender papayawhip cadetblue lavenderblush peachpuff chartreuse lawngreen peru chocolate lemonchiffon pink coral lightblue plum cornflowerblue lightcoral powderblue cornsilk lightcyan purple crimson lightgoldenrodyellow red cyan lightgray rosybrown darkblue lightgreen royalblue darkcyan lightpink saddlebrown darkgoldenrod lightsalmon salmon darkgray lightseagreen sandybrown darkgreen lightskyblue seagreen darkkhaki lightslategray seashell darkmagenta lightsteelblue sienna darkolivegreen lightyellow silver darkorange lime skyblue darkorchid limegreen slateblue darkred linen slategray darksalmon magenta snow darkseagreen maroon springgreen darkslateblue mediumaquamarine steelblue darkslategray mediumblue tan darkturquoise mediumorchid teal darkviolet mediumpurple thistle deeppink mediumseagreen tomato deepskyblue mediumslateblue turquoise dimgray mediumspringgreen violet dodgerblue mediumturquoise wheat firebrick mediumvioletred white floralwhite midnightblue whitesmoke forestgreen mintcream yellow fuchsia mistyrose yellowgreen gainsboro moccasin ----------------------------------------------------

Shading patterns

fpattern ------------------------- nil clear solid horzStripe vertStripe reverseDiagStripe diagStripe horzCross diagCross thinHorzStripe thinVertStripe thinReverseDiagStripe thinDiagStripe thinHorzCross thinDiagCross pct5 pct10 pct12 pct15 pct20 pct25 pct30 pct35 pct37 pct40 pct45 pct50 pct55 pct60 pct62 pct65 pct70 pct75 pct80 pct85 pct87 pct90 pct95 -------------------------

Underline patterns

upattern ------------------------- none single words double thick dotted dottedHeavy dash dashedHeavy dashLong dashLongHeavy dotDash dashDotHeavy dotDotDash dashDotDotHeavy wave wavyHeavy wavyDouble -------------------------

Border patterns

bpattern ------------------------- nil single thick double dotted dashed dotDash dotDotDash triple thinThickSmallGap thickThinSmallGap thinThickThinSmallGap thinThickMediumGap thickThinMediumGap thinThickThinMediumGap thinThickLargeGap thickThinLargeGap thinThickThinLargeGap wave doubleWave dashSmallGap dashDotStroked threeDEmboss threeDEngrave outset inset -------------------------


© Copyright 1996–2018 StataCorp LLC   |   Terms of use   |   Privacy   |   Contact us   |   What's new   |   Site index