{smcl}
{* *! version 1.0.0  24oct2007}{...}
{cmd:help survci} 
{hline}

{title:Title}

{p2colset 5 15 15 0}{...}
{p2col :{hi:survci} {hline 2}}Pointwise confidence bands for the covariate-adjusted survivor function after {cmd:stcox}{p_end}
{p2colreset}{...}


{title:Syntax}

{p 8 43 2}
{opt survci} {ifin} [{cmd:,} {it:options}]

{synoptset 32 tabbed}{...}
{marker options}{...}
{synopthdr}
{synoptline}
{syntab:Main}
{synopt:{cmdab:bases:urv(}{it:{bf:{help varname}}}{cmd:)}}use baseline survivor function {it:varname}{p_end}
{synopt:{cmd:at(}{it:#} {it:# ...}{cmd:)}}values of the specified
covariates; default is means of the covariates{p_end}
{synopt:{cmdab:cl:type(loglog|log|normal)}}type of the transformation for the
confidence bands; default is {cmd:loglog}{p_end}
{synopt :{opt l:evel(#)}}set confidence level; default is {cmd:level(95)}{p_end}
{synopt:{cmdab:out:file(}{it:filename}[{cmd:,} {cmd:replace}]{cmd:)}}save the 
plot data to {it:filename}; use {cmd:replace} to overwrite existing 
{it:filename}{p_end}

{syntab:Y axis, X axis, Titles, Legend}
{synopt:{it:{help twoway_options}}}any options other than {cmd:by()}
documented in {bind:{bf:[G] {it:twoway_options}}}{p_end}
{synoptline}
{p2colreset}{...}


{title:Description}

{pstd}
{cmd:survci} plots pointwise confidence bands for the covariate-adjusted
survivor function after {cmd:stcox}.  Estimates of the survivor function,
standard errors, and lower and upper bounds may be optionally saved.


{title:Options}

{dlgtab:Main}

{phang}
{opt basesurv(varname)} specifies the name of the variable containing the
estimates of the baseline survivor function.  By default, it uses the variable
in {cmd:e(bases)} saved by {cmd:stcox}.

{phang}
{opt at(# # ...)} specifies the values of the covariates used in {cmd:stcox}
for which the estimates of the survivor function are to be computed.  The
number of values should be the same as the number of covariates specified with
{cmd:stcox}.  By default, means of the continuous covariates and 0 for the
binary covariates are used.

{phang}
{cmd:cltype(loglog|log|normal)} specifies the transformation of the confidence
intervals to be used in the computation.  The default is {cmd:loglog}.  This
interval is of the form [S^exp(z*se/S/ln(S)), S^exp(-z*se/S/ln(S))] where S is
the estimated survivor function, se is the standard error of S, and z is the
normal-based critical value.  If {cmd:log} is specified the confidence
interval [S*exp(-z*se/S), S*exp(z*se/S)] is computed.  If {cmd:normal} is
specified the confidence interval [S-z*se, S+z*se] is computed.

{phang}
{opt level(#)} specifies the confidence level, as a percentage, for the
pointwise confidence interval of the survivor function; see {manhelp level R}.

{phang}
{cmd:outfile(}{it:filename}[{cmd:,} {cmd:replace}]{cmd:)} creates a Stata data
file ({cmd:.dta} file) containing the values used to produce a graph.
{cmd:replace} indicates that {it:filename} be overwritten, if it exists.

{dlgtab:Y axis, X axis, Titles, Legend, Overall}

{phang}
{it:twoway_options} are any of the options documented in 
{manhelpi twoway_options G}.  These include options for titling the graph (see 
{manhelpi title_options G}) and for saving the graph to disk (see
{manhelpi saving_option G}).


{title:Remarks}

{pstd}
The formula for the asymptotic variance of the covariate-adjusted survivor
function is given in Marubini and Valsecchi (1995, 221), among others, and is
based on the asymptotic variance of the cumulative hazard function derived by
Tsiatis (1981).  The pointwise confidence intervals are computed using one of
the three transformations as described above in the description of
{cmd:cltype()}.  The estimates are not available with survey or
multiple-record survival data.


{title:Examples}

{pstd}
Plot pointwise confidence bands for the survivor function adjusted for
{cmd:age=60} using the product-limit estimate of the baseline survivor
function.{p_end}
	{cmd:. sysuse cancer}
	{cmd:. stset studytime, failure(died)}
	{cmd:. stcox age, basesurv(s0)}
	{cmd:. survci, at(60)}

{pstd}
Plot pointwise confidence bands for the survivor function adjusted for
{cmd:age=60} using the estimate of the baseline survivor
function based on the cumulative hazard.{p_end}
	{cmd:. stcox age, basech(h0)}
	{cmd:. gen double s0_ch = exp(-h0)}
	{cmd:. survci, at(60) basesurv(s0_ch)}

{pstd}
Request log-based confidence intervals in the above.{p_end}
	{cmd:. survci, at(60) basesurv(s0_ch) cltype(log)}

{p2colreset}{...}


{title:References}

{phang}
Marubini, E., and M. G. Valsecchi. 1995.
{it: Analysing Survival Data from Clinical Trials and Observational Studies},
UK: Wiley.
{p_end}

{phang}
Tsiatis, A. A. 1981.
A large sample study of the estimate for the integrated hazard function in
Cox's regression model for survival data.
{it:Annals of Statistics} 9: 93-108.{p_end}


{title:Also see}

{psee}
Online:  {manhelp stcurve ST}, {manhelp stcox ST}, {manhelp stset ST}
{p_end}