{smcl}
{* *! version 1.1.2  Mar2008}{...}
{cmd:help dunnett}
{hline}

{title:Title}

{p2colset 9 20 22 2}{...}
{p2col :{hi: dunnett} {hline 2 }}The Dunnett method for a comparison 
of all treatment means with a control mean{p_end}
{p2colreset}{...}


{title:Syntax}

{p 8 15 2}
{cmdab:dunnett}
{it:response_var}
{it:factor_var}
{ifin}{cmd:,}
{opt con:trol(#)}
[{it:options}]

{synoptset 20 tabbed}{...}
{synopthdr}
{synoptline}
{syntab:Main}
{p2coldent:* {opt con:trol(#)}}set control value of {it:factor_var} {p_end}
{synopt :{opt l:evel(#)}}set confidence level; the default is {cmd:level(95)} {p_end}
{synopt :{opt one:sided}}set interval type to one-sided; the default is two-sided intervals {p_end}
{synopt :{opt no:label}}show numeric codes, not labels {p_end}
{synopt :{opt sep:arator(#)}}draw separator line after every {it:#} groups; default
is {cmd:separator(5)}{p_end}
{synopt :{opt mi:ssing}}treat missing values of {it:factor_var} as a category {p_end}
{synoptline}{...}
{p2colreset}
{p 4 6 2}
  * {opt control(#)} is required.{p_end}

{title:Description}

{pstd}
The {opt dunnett} command compares all group means to a control group mean by
 implementing Dunnett's test. Simultaneous confidence intervals for differences between
each individual group mean and the control mean are reported using the tables
from Dunnett (1955) and Dunnett (1964).

{pstd}
Because the table values are used, the {opt dunnett} command can only construct 95% and 99%
 simultaneous confidence intervals and requires that the degrees of freedom be 
at least five. The Dunnett method also requires that all treatments have the same sample size
for the validity of the test to hold.

{pstd} 
If a two-sided test is specified, the number of groups in {it: factor_var} must be less 
than 21 including the control. If a one-sided test is specified, the number of groups 
must be less than 10 including the control. Taking the conservative approach, the {opt dunnett}
 command rounds the degrees of freedom to the lower value given in the tables. 

{pstd}
The tables produced by this command may be wider than the number of default
columns set in Stata. You may want to increase the number of columns so that
the tables will properly display in the Results window. 

{title:Options}

{dlgtab:Main}

{phang}{opt control} specifies the control value of factor_var that {opt dunnett} will use 
as the control to compare all other groups to. This value must be numeric and a value of 
factor_var.

{phang}{opt level(#)} specifies the confidence level, as a percentage, for simultaneous confidence 
intervals. The default is {cmd: level(95)} and can currently only be changed to {cmd: level(99)}.

{phang}{opt onesided} specifies that one-sided simultaneous confidence intervals be constructed. 
The default is to construct two-sided simultaneous confidence intervals. When {cmd: onesided} is specified,
 both the lower and upper simultaneous bounds are reported for a lower and upper tailed test respectively.

{phang}{opt nolabel} causes the numeric codes to be displayed rather than the value
labels in the reported table. The default is to show the value labels if they exist.

{phang}{cmd: separator(#)} specifies how often to insert separation lines into the output. 
The default is {cmd: separator(5)}, meaning that a line is drawn after every five treatments. 
{cmd: separator(10)} would draw a line after every 10 treatments and {cmd: separator(0)} suppresses
the separation line.

{phang}{opt missing} requests that missing values of {it: factor_var} be 
treated as a category rather than as observations to be omitted from the 
analysis.

{title:Examples}

    Setup
{phang2}{cmd:. webuse rash}{p_end}

{phang}Two-sided simultaneous confidence intervals{p_end}
{phang2}{cmd:. dunnett response clinic, control(1)}{p_end}

{phang}One-sided simultaneous confidence intervals{p_end}
{phang2}{cmd:. dunnett response clinic, control(1) onesided}{p_end}

{phang}One and two-sided 99% simultaneous confidence intervals{p_end}
{phang2}{cmd:. dunnett response clinic, control(1) level(99)}{p_end}
{phang2}{cmd:. dunnett response clinic, control(1) onesided level(99)}{p_end}

    Setup
{phang2}{cmd:. webuse rash}{p_end}
{phang2}{cmd:. replace clinic = . if clinic == 8}{p_end}

{phang}Treat missing values as a category{p_end}
{phang2}{cmd:. dunnett response clinic, control(1) missing}{p_end}


{title:Saved results}

{pstd}
{cmd:dunnett} saves the following in {cmd:r()}:

{synoptset 17 tabbed}{...}
{p2col 5 15 19 2: Scalars}{p_end}
{synopt:{cmd:r(N)}}total number of observations{p_end}
{synopt:{cmd:r(groups)}}number of groups including the control{p_end}
{synopt:{cmd:r(df)}}degrees of freedom{p_end}
{synopt:{cmd:r(mse)}}mean squared error{p_end}
{synopt:{cmd:r(side)}}type of test{p_end}
{synopt:{cmd:r(confidence)}}confidence level of SCI{p_end}
{synopt:{cmd:r(reps)}}number of replications for each group{p_end}
{synopt:{cmd:r(d)}}table value{p_end}
{synopt:{cmd:r(criterion)}}Dunnett criterion{p_end}
{synopt:{cmd:r(control)}}control value{p_end}

{p2col 5 15 19 2: Macros}{p_end}
{synopt:{cmd:r(fact_var)}}factor variable{p_end}
{synopt:{cmd:r(resp_var)}}response variable{p_end}
{p2colreset}{...}

{title:References}

{pstd}
Dunnett, C.W. (1955). “A multiple comparisons procedure 
for comparing several treatments with a control.” 
Journal of the American Statistical Association 509, 1096-1121.

{pstd}
Dunnett, C.W. (1964). “New tables for multiple comparisons 
with a control.” Biometrics 20 482-491

{pstd}
Kuehl, R.O. (1994). Design of Experiments: Statistical 
Principles of Research Design and Analysis. 2nd edition


{title:Author}

{phang2}Theresa Boswell{p_end}
{phang2}tmb@stata.com{p_end}

{title:Also see}

{psee}
Online:  {manhelp oneway R},
{manhelp anova R},
{manhelp loneway R}
{p_end}


{s6hlp}
{smcl}