* Stata 3.0 version 1.0.0 JPR 6.2.92.
* NL - Max likelihood estimation of non-linear model, based on NONLIN.ADO.
program define _nlout
	version 3.0
	local level `1'
	mac def S_1 $S_E_nobs	/* Number of observations */
	mac def S_2 $S_E_ssm	/* model sum of squares */
	mac def S_3 $S_E_dfm 	/* model degrees of freedom */
	mac def S_4 $S_E_ssr 	/* residual sum of squares */
	mac def S_5 $S_E_dfr 	/* residual degrees of freedom */
	mac def S_6 $S_E_f 	/* model F-statistic */
	mac def S_7 $S_E_rsq 	/* R-square */
	mac def S_8 $S_E_rsqa 	/* adjusted R-square */
	mac def S_9 $S_E_sdr 	/* residual root mean square */
	mac def S_10 $S_E_devi	/* residual deviance (-2 * log likelihood) */
	mac def S_11 $S_E_gm2 	/* geom mean (y-k)]^2 if lnlsq(k), else 1 */
	mac def S_12 $S_E_cnvr 	/* 0 if convergence failed, 1 otherwise */

	#delimit ;
	di in gr _n "  Source |       SS       df       MS   " 
		_col(54) "Number of obs = " in ye %9.0f $S_E_nobs ;
	di in gr "---------+------------------------------"
		 in gr _col(54) "F(" %3.0f $S_E_dfm "," %6.0f $S_E_dfr 
		") = " in ye %9.2f $S_E_f ;
	di in gr "   Model | " in ye %11.0g $S_E_ssm " " %5.0f $S_E_dfm 
		" " %11.0g $S_E_msm
		in gr _col(54) "Prob > F      = " 
		in ye %9.4f fprob($S_E_dfm,$S_E_dfr,$S_E_f) ;
	di in gr "Residual | " in ye %11.0g $S_E_ssr " " %5.0f $S_E_dfr 
		" " %11.0g $S_E_msr
		 in gr _col(54) "R-square      = " in ye %9.4f $S_E_rsq ;
	di in gr "---------+------------------------------"
		 in gr _col(54) "Adj R-square  = " in ye %9.4f $S_E_rsqa ;

	di in gr "   Total | " in ye %11.0g $S_E_sst " " %5.0f $S_E_dft
		" " %11.0g $S_E_sst/$S_E_dft
		in gr _col(54) "Root MSE      = " 
		in ye %9.0g $S_E_sdr ;
	di in gr _col(54) "Res. dev.     = " in ye %9.0g $S_E_devi ;
		#delimit cr
/*
	Display coefficients, standard errors and ci's
*/
	if `level'<10 | `level'>99 { 
		local level $S_level
	}
	local invt = invt($S_E_dfr, `level'/100) 

	local skip = 8-length("$S_E_depv")
	di in gr "$S_E_ttl" 
	if "$S_E_ttl2" != "" { 
		di "$S_E_ttl2"
	}
	di in gr _dup(78) "-"
	di in gr _skip(`skip') /*
*/  "$S_E_depv |      Coef.   Std. Err.       t     P>|t|       [`level'% Conf. Interval]"
	di in gr _dup(78) "-"

	parse "$S_E_rhs", parse(" ")
	local j 1
	while `j' <= $S_E_np {
		* ``j'' is name 
		* parameter value is ${`name'} = ${``j''}
		local name "``j''"
		local tst = ${`name'}/_se[`name']
		local tprob = tprob($S_E_dfr,`tst')
		local cil = ${`name'}-`invt'*_se[`name']
		local cih = ${`name'}+`invt'*_se[`name']
		if $S_E_cj == `j' {
			local star "*"
		}
		else local star " "
		local skip = 8-length("`name'")
		#delimit ;
		di in gr _skip(`skip') "`name'`star'|" in ye
			"  " %9.0g ${`name'}
			"  " %9.0g _se[`name']
			"  " %9.3f `tst' "  " %6.3f `tprob'
			"      " %9.0g `cil' "   " %9.0g `cih'
		;
		#delimit cr
		local j = `j'+1
	}
	di in gr _dup(78) "-"
	if $S_E_cj ~= 0 {
		di in gr /*
	*/ "* Parameter taken as constant term in model & ANOVA table"
		}
	* di _n in gr "Correlations between parameter estimates"
	* correlate, _coef
	di in gr /*
*/ " (SE's, P values, CI's, and correlations are asymptotic approximations)"
	if $S_E_cnvr ~= 1 {
		error 430
	}
end