*! cialpha by MJB/AT version 2.0  March2000   (STB-56: sg143)
* cialpha by MJB/AT version 1.1  April1999

program define cialpha, rclass
	version 6.0
	local options "level(int 95)*"
	parse "`*'"

	if ( r(alpha)==. & r(k)==.)  {	
		display in red "ERROR: Last estimates not found" 
		display in red "Can only be used after alpha command"
		exit
	} 
	else {
		local alpha = r(alpha)
		local k = r(k)
		local n = _result(1)
		local df1 = `n'-1
		local df2 = (`k'-1)*(`n'-1)
		local p = (100-`level')/100
		local f = invfprob(`df1',`df2',`p') 
		local ci = 1-((1-`alpha')*`f')
		if ( (`ci'<0) | (`ci'>`alpha') ) {
			local ci = 0
		}
		di 
		di in gr " Cronbach's alpha one-sided confidence interval"
		di in gr "------------------------------------------------------------------------------"
		di in gr _col(2) "Items" _col(10) "|   alpha" _col(31) "[" `level' "% Conf.Interval]"
		di in gr "---------+--------------------------------------------------------------------"
		di in gr _col(2)  "Test" _col(10) in gr "|" _col(14) in ye `alpha' _col(26) in gr ">=" /*
		*/ _col(35) in ye `ci'
		di in gr "------------------------------------------------------------------------------"

		return scalar alpha = `alpha'
		return scalar k = `k'
		return scalar n = `n'
		return scalar ci = `ci'
		return scalar level = `level'
	}
end