*! 1.0.1 NJC 7 Jan 1999         STB-48 gr35
* 1.0.0  NJC 2 Feb 1998
program define psm
        version 5.0
        local varlist "req ex max(1)"
        local if "opt"
        local in "opt"
        #delimit ;
        local options "Symbol(string) noBorder Connect(string) YLAbel(string)
        XLAbel(string) GRid *" ;
        #delimit cr
        parse "`*'"

        capture assert "$S_a" != "" & "$S_b" != "" & "$S_q" != ""
        if _rc {
                di in r "needs macros S_a, S_b and S_q"
                exit 198
        }

        tempvar touse F Psubi
        qui {
                gen byte `touse' = cond(`varlist' == .,.,1) `if' `in'
                gen float `F' = /*
                 */ 1 - ( 1 / ( 1 + (`varlist' / $S_b)^$S_a)^$S_q) if `touse'
                sort `varlist'
                gen float `Psubi' = sum(`touse')
                replace `Psubi' = cond(`F' == .,.,(`Psubi'-0.5)/`Psubi'[_N])
        }

        if "`symbol'" == "" { local symbol "oi" }
        else { local symbol "`symbol'i" }
        if "`connect'" == "" { local connect ".l" }
        else { local connect "`connect'l" }
        if "`ylabel'" == "" { local ylabel "0,.25,.5,.75,1" }
        if "`xlabel'" == "" { local xlabel "0,.25,.5,.75,1" }
        if "`grid'" != "" { local grid "yli(.25,.5,.75) xli(.25,.5,.75)" }
        local yl: variable label `varlist'
        if "`yl'"=="" { local yl "`varlist'" }
        label var `F' "Singh-Maddala F[`yl']"
        label var `Psubi' "Empirical P[i] = (i-0.5) / N"
        format `F' `Psubi' %9.2f
        if "`border'" == "" { local bo "border" }

        graph `F' `Psubi' `Psubi', c(`connect') s(`symbol') /*
         */ ylab(`ylabel') xlab(`xlabel') `bo' `grid' `options'
end