*! version 1.0  J. Hilbe 12/16/96   STB-41 sg53.2
* Grouped complementary log-log regression; like blogit/bprobit
program define bcloglog
        version 5.0 
        local options "Level(integer $S_level)"
        if "`*'"=="" | substr("`1'",1,1)=="," { 
                if "$S_E_cmd"!="bcloglog" { error 301 }
                parse "`*'"
                cloglog, level(`level')
                exit
        }
        local varlist "req ex min(2)"
        local if "opt"
        local options "`options' LOg *"
        parse "`*'"
        if "`log'"=="" { local log "nolog" } 
        parse "`varlist'", parse(" ")
        confirm new var _outcome
        if `level'<10 | `level'>99 { local level 95 } 
        local k = _N
        local k1 = _N + 1
        tempvar pop
        quietly expand =2, clear
        capture {
                gen byte _outcome=0 in 1/`k'
                replace _outcome=1 in `k1'/l
                gen `pop'=`2'-`1' in 1/`k'
                replace `pop'=`1' in `k1'/l
                mac shift
                mac shift
                noisily cloglog _outcome `*' [freq=`pop'] `if', /*
                        */ level(`level') `options' `log' 
                mac def S_E_nobs=_result(1)
                mac def S_E_ll=_result(2)
                mac def S_E_mdf=_result(3)
                mac def S_E_cmd "bcloglog"
        }
        local rc = _rc
        quietly keep in 1/`k'
        capture drop _outcome
        error `rc'
end