*! version 1.1.0 20 November 1996 STB-36 gr16.1
* N.J. Cox, University of Durham
* convex hull plot
program def chplot
    version 4.0
    local varlist "req ex min(2) max(2)"
    local if "opt"
    local in "opt"
    #delimit ;
    local options "Hull(int 1) HV(str) MOVIE
    Connect(str) Symbol(str) T1title(str) L1title(str)  *" ;
    #delimit cr
    parse "`*'"
    parse "`varlist'", parse(" ")
    if "`hv'" != "" {
        confirm new variable `hv'1
    }
    else {
        confirm new variable _hull1
        local hv "_hull"
    }
    preserve
    if "`if'" != "" | "`in'" != "" {
        qui keep `if' `in'
    }

    tempvar coname dr hullvar
    if "`movie'" == "" | `hull' == 1 { local nograph "nograph" }
    qui conhull `2' `1' , hull(`hull') coname(`coname') `nograph'
    set graphics off
    qui condraw `2' `1' `coname', hull(`hull') vid(`hv') dr(`dr')
    set graphics on
    if "`connect'" == "" { local connect ".l" }
    if "`symbol'" == "" { local symbol "oi" }
    if "`t1title'" == "" { local t1title " " }
    local varlaby : var label `1'
    if "`varlaby'" == "" { local varlaby "`1'" }
    if "`l1title'" == "" { local l1title "`varlaby'" }
    gra `1' `hv'1 `2' , connect(`connect') sy(`symbol') t1("`t1title'") /*
     */ l1("`l1title'") `options'

end