program define _result
*! version 1.1.1 12Feb96                (STB-30: dm41)

   version 4.0
   if "`1'" == "_all" {
      help _res_all
      exit
   }
   #delimit ;
   local cmd5d "3 1 3";
   local CMD5d "count describe inspect";
   local hlp5d "5dcn 5dds 5din";
   local cmd5s "5 2 4 6 7 4 3 4 3 3 7 3 3 3 6 7 8 4 4 4 2 5 4";
   local CMD5s "_qreg anova areg blogit bprobit clogit cnreg corc correlate cox 
       dprobit factor fit glm glogit gprobit logistic logit mlogit ologit
       oneway oprobit probit";
   local hlp5s "5sqr 5srg 5srg 7max 7max 7max 7max 5srg 5scr 7max 7max 5sfa
       5srg 5srg 5srg 5srg 7max 7max 7max 7max 5s1w 7max 7max";
   local cmd5S "5 3 4 2 2 7 5 7 7 8 7 8 7 4 4 4 2 2 8 3";
   local CMD5S "regdw regress rreg stepwise summarize swcnreg swcox swlogis
       swlogit swologit swoprbt swprobit swtobit tab1 tab2 tabi tabulate
       test testparm tobit";
   local hlp5S "5srg 5srg 5srr 5srg 5sum 7max 7max 7max 7max 7max 7max 7max
       7max 5sta 5sta 5sta 5sta 5sts 5sts 7max";
   local cmd6a "4";
   local CMD6a "version";
   local hlp6a "6avr";
   local cmd6m "2 4 2 4";
   local CMD6m "accum glsaccum mlout vecaccum";
   local hlp6m "6mac 6mac 6mlo 6mac";
   #delimit cr

   global S_1 "`1'"
   local tail "5s"
   if "mat" <= "`1'" & "`1'" <= "matrix" {
      local tail "6m"
      global S_1 `2'
   }
   else {
      local m1 : word count `CMD5s'
      local m1 : word `m1' of `CMD5s'
      if "`1'" > "`m1'" { local tail "5S" }
   }
   global S_2 `cmd`tail''
   _resx `CMD`tail''
   if !$S_2 {
      local tail "5d"
      global S_2 `cmd5d'
      _resx `CMD5d'
   }
   if !$S_2 {
      local tail "6a"
      global S_2 = ("vers"<="`1'" & "`1'" <= "version")
   }
   if $S_2 {
      local m1 : word $S_2 of `hlp`tail''
      help _res`m1'
   }
   else { noi di "_result() contents not documented for " in wh "$S_1" }
end



program define _resx

   local j : word count `*'
   local j = `j' + 1
   local i 0
   while `j' != `i' + 1 {
      local m = int((`i'+`j')/2)
      local k1 : word `m' of `*'
      local k : word `m' of $S_2
      local k1 = substr("`k1'", 1, `k')
      if "`k1'" <= "$S_1" { local i `m' }
      else { local j `m' }
   }
   if `i' { local k1 : word `i' of `*' }
   global S_2 = `i'*("$S_1" <= "`k1'")
end