*! v 3.1.1 PR 14-Nov-94.                (sg26.3: STB-25)
program define _jprfpin
	version 3.1
	local df `1'
	local cmd "`2'"
	local gplot `3'
	local saving "`4'"
	if `df'==0 | `df'<-1 {
		di in red "invalid df"
		exit 198
	}
	local df3=`df'==3
	local df4=`df'==4
	local meq2=`df'>2|`df'==-1
	if "`cmd'"=="" { local cmd "reg" }
	local anova="`cmd'"=="anova"
	local qreg="`cmd'"=="qreg"
	local normal=`anova'|("`cmd'"=="reg")|("`cmd'"=="fit")|("`cmd'"=="rreg")
	local glm=(substr("`cmd'",1,3)=="glm")
	local blogit=("`cmd'"=="blogit"|"`cmd'"=="bprobit")
/*
	dist=0 (normal), 1 (binomial), 2 (poisson), 3 (cox), 4 (glm),
	5 (mlogit)
*/
	local dist= /*
	*/ (`blogit'|"`cmd'"=="logit"|"`cmd'"=="logistic"|"`cmd'"=="probit") /*
	*/ + 2*("`cmd'"=="poisson") + 3*("`cmd'"=="cox") + 4*`glm' /*
	*/ + 5*("`cmd'"=="mlogit")
	local graph=`gplot'>-1
	if "`saving'"!="" {
		if `graph' { local saving "sav(`saving')" }
		else {
			di in red "saving() requires gplot()"
			exit 198
		}
	}
	global S_1 `df'
	global S_2 `df3'
	global S_3 `df4'
	global S_4 `meq2'
	global S_5 "`cmd'"
	global S_6 `anova'
	global S_7 `normal'
	global S_8 `qreg'
	global S_9 `glm'
	global S_10 `blogit'
	global S_11 `dist'
	global S_12 `graph'
	global S_13 "`saving'"
end