* see comments at end-of-file
				
program define gr3set
version 2.1
{
	while "%_1"!="" { 
		mac def _l = length("%_1")
		if "%_2"=="" {
			di in blu "(no value specified for %_1, unchanged)"
		}
		else if "%_1"==substr("axis",1,%_l) { 
			if "%_2"=="min" | "%_2"=="0" | /* 
			*/ "%_2"=="out" | "%_2"=="tbl" { 
				mac def D3axis "%_2"
			}
			else di in blu "(invalid axis type %_2)"
		}
		else if "%_1"==substr("shadow",1,%_l) { 
			if "%_2"=="on" | "%_2"=="off" { mac def D3shad "%_2" }
			else di in blu "(invalid shadow)"
		}
		else {
			capture confirm integer number %_2
			if _rc { 
				di in blu "(%_2 found where integer expected)"	
			}
			else {
				if "%_1"==substr("rotate",1,%_l) {
					mac def D3rot %_2
				}
				else if "%_1"==substr("elev",1,%_l) { 
					mac def D3elev %_2
				}
				else di in blu "(%_1 invalid)"
			}
		}
		mac shift
		mac shift
	}
	gr3q
end
exit

/*
	gr3set [element [element ..]]
	where
		element :=	axis { 0 | tbl | min | out }
				rotate <angle>
				elev <angle>
				shadow { on | off }

	The keywords in the element may be abbreviated down to one character.
*/