*! etoj -- Convert Stata elapsed dates to Julian dates.         STB-14: dm14.1
*! version 1.0.0        June 1993       Sean Becketti
program define etoj
        version 3.0
        local varlist "req ex min(1) max(1)"
        local if "opt pre"
        local in "opt pre"
        local options "Generate(str)"
        parse "`*'"
        conf new v `generat'
        parse "`generat'", parse(" ")
        local year "`1'"
        local day "`2'"
        local ifday = 1
        if "`day'"=="" {
                local ifday = 0
                tempvar day
        }
        quietly {
                tempvar m d y
                etomdy `varlist' `if' `in', gen(`m' `d' `y')
                replace `m' = 1 `if' `in'
                replace `d' = 1 `if' `in'
                tempvar jan1
                mdytoe `m' `d' `y' `if' `in', gen(`jan1')
                gen int `day' = `varlist' - `jan1' + 1 `if' `in'
                if (`ifday') { gen int `year' = `y' `if' `in'}
                else { gen float `year' = `y' + (`day'/1000) `if' `in'}
        }
end