*! version 1.0.2 -- 02/02/93 STB-13: ip4
program define pause 
	version 3.0
	if "`1'"=="on" | "`1'"=="off" {
		if "`2'"=="" {
			if "`1'"=="on" { 
				mac def PAUSEON "yes"
			}
			else	mac def PAUSEON
			exit
		}
	}
	if "$PAUSEON"=="" { exit }
	set output proc 			/* overrides quietly 	*/
	di in blue "pause:  `*'"
	while 1 { 
		local cmd "*"
		capture {
			set output proc
			while "`cmd'"!="end" {
				capture {
					set output proc
					`cmd'
				}
				if _rc {
					di in blue "r(" _rc ");"
				}
				di in wh "-> " _request(_cmd)
				capture di "`cmd'"	/* chk double quotes */
				if _rc { exit 3001 } 
				if "`cmd'"=="BREAK" { 
					exit 3000
				}
				if "`cmd'"=="q" {
					local cmd "end"
				}
			}
			di in blue "execution resumes..."
			exit
		}
		set output proc
		if _rc==1 {
			di in red "--Break--  " in bl "(Type " in wh /* 
			*/ "BREAK" in blu /*
			*/ " to send real break back to calling program)"
		}
		else if _rc==3000 {
			di in bl "sending Break to calling program..."
			exit 1
		}
		else {
			capture {			/* has double quotes */
				set output proc
				`cmd'
			}
			if _rc {
				di in blue "r(" _rc ");"
			}
		}
			
	}
	/*NOTREACHED*/
end